[arch-commits] Commit in visidata/repos (community-any community-any/PKGBUILD)

[Caleb Maclennan]

    Date: Saturday, April 9, 2022 @ 09:01:23
  Author: alerque
Revision: 1183111

archrelease: copy trunk to community-any

Added:
  visidata/repos/community-any/
  visidata/repos/community-any/PKGBUILD
    (from rev 1183110, visidata/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: visidata/repos/community-any/PKGBUILD (from rev 1183110, visidata/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2022-04-09 09:01:23 UTC (rev 1183111)
@@ -0,0 +1,57 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Pig Monkey <pm at pig-monkey.com>
+# Contributor: Caltlgin Stsodaat <contact at fossdaily.xyz>
+# Contributor: Javier Tiá <javier dot tia at gmail dot com>
+
+pkgname=visidata
+pkgver=2.8
+pkgrel=2
+pkgdesc='Terminal spreadsheet multitool for discovering and arranging data'
+arch=(any)
+url=https://www.visidata.org
+license=(GPL3)
+depends=(python
+         python-dateutil)
+optdepends=('python-dnslib: pcap support'
+            'python-fonttools: ttf/otf support'
+            'python-h5py: hdf5 support'
+            'python-lxml: html/xml support'
+            'python-openpyxl: xlsx support'
+            'python-pandas: dta (Stata) support'
+            'python-pdfminer: pdf support'
+            'python-psycopg2: postgres support'
+            'python-pyaml: yaml/yml support'
+            'python-pypng: png support'
+            'python-requests: http support'
+            'python-tabulate: tabulate saver support'
+            'python-vobject: vcf support'
+            'python-wcwidth: tabulate saver with unicode support'
+            'python-xlrd: xls support')
+# optdepends+=( # AUR only optdepends
+#             'python-dpkt: pcap support'
+#             'python-mapbox-vector-tile: mbtiles support'
+#             'python-namestand: graphviz support'
+#             'python-pyshp: shapefiles support')
+makedepends=(python-{build,installer}
+             python-setuptools
+             python-wheel)
+checkdepends=(python-pytest)
+_archive="$pkgname-$pkgver"
+source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$_archive.tar.gz")
+sha256sums=('26d6cdacdca394a4820bda7f142746e190c49a7871c109f477f8ffddc1ccd0c9')
+
+build() {
+	cd "$_archive"
+	python -m build -wn
+}
+
+check() {
+	cd "$_archive"
+	pytest
+}
+
+package() {
+	cd "$_archive"
+	python -m installer -d "$pkgdir" dist/*.whl
+	install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+}