[arch-commits] Commit in haskell-tasty-lua/repos (2 files)

[Felix Yan]

    Date: Sunday, April 10, 2022 @ 11:37:13
  Author: felixonmars
Revision: 1184497

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-tasty-lua/repos/community-staging-x86_64/
  haskell-tasty-lua/repos/community-staging-x86_64/PKGBUILD
    (from rev 1184496, haskell-tasty-lua/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: haskell-tasty-lua/repos/community-staging-x86_64/PKGBUILD (from rev 1184496, haskell-tasty-lua/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-04-10 11:37:13 UTC (rev 1184497)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=tasty-lua
+pkgname=haskell-tasty-lua
+pkgver=1.0.1
+pkgrel=5
+pkgdesc="Write tests in Lua, integrate into tasty."
+url="https://github.com/hslua/tasty-lua"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-file-embed' 'haskell-hslua-core' 'haskell-hslua-marshalling'
+         'haskell-lua-arbitrary' 'haskell-quickcheck' 'haskell-tasty')
+makedepends=('ghc' 'haskell-tasty-hunit')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('9bc278f965b9ed89025bd162a6c10de2bd4d806935be35774889fd1185e7d5f1cd106cf32296118f86922ab11e462a1f7a6438bf79925d6a29830bd3f2df4b34')
+
+build() {
+    cd $_hkgname-$pkgver    
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}