[arch-commits] Commit in (hut hut/repos hut/trunk hut/trunk/PKGBUILD)

[George Rawlinson]

    Date: Sunday, April 10, 2022 @ 19:16:07
  Author: grawlinson
Revision: 1185758

addpkg: hut 0.1.0-2

Added:
  hut/
  hut/repos/
  hut/trunk/
  hut/trunk/PKGBUILD

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Added: hut/trunk/PKGBUILD
===================================================================
--- hut/trunk/PKGBUILD	                        (rev 0)
+++ hut/trunk/PKGBUILD	2022-04-10 19:16:07 UTC (rev 1185758)
@@ -0,0 +1,54 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Thorben Günther <echo YWRtaW5AeGVucm94Lm5ldAo= | base64 -d>
+
+pkgname=hut
+pkgver=0.1.0
+pkgrel=2
+pkgdesc='A CLI tool for Sourcehut'
+arch=('x86_64')
+url='https://sr.ht/~emersion/hut'
+license=('AGPL3')
+depends=('glibc')
+makedepends=('git' 'go' 'scdoc')
+options=('!lto')
+_commit='2bc780f40a6be4fbf0fd98efb125798b685ac240'
+source=("git+https://git.sr.ht/~emersion/hut#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+prepare() {
+  cd "$pkgname"
+
+  # download dependencies
+  go mod download
+}
+
+build() {
+  cd "$pkgname"
+
+  # set Go flags
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+
+  make --environment-overrides
+}
+
+check() {
+  cd "$pkgname"
+
+  go test -v ./...
+}
+
+package() {
+  cd "$pkgname"
+
+  make PREFIX=/usr DESTDIR="$pkgdir" install
+}