[arch-commits] Commit in (hck hck/repos hck/trunk hck/trunk/PKGBUILD)

[George Rawlinson]

    Date: Monday, April 11, 2022 @ 01:59:58
  Author: grawlinson
Revision: 1185812

addpkg: hck 0.7.1-2

Added:
  hck/
  hck/repos/
  hck/trunk/
  hck/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Added: hck/trunk/PKGBUILD
===================================================================
--- hck/trunk/PKGBUILD	                        (rev 0)
+++ hck/trunk/PKGBUILD	2022-04-11 01:59:58 UTC (rev 1185812)
@@ -0,0 +1,48 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: aulonsal <aulonsal at gmail dot com>
+
+pkgname=hck
+pkgver=0.7.1
+pkgrel=2
+pkgdesc='A drop in replacement for cut that can use a regex delimiter instead of a fixed string'
+arch=('x86_64')
+url='https://github.com/sstadick/hck'
+license=('Unlicense' 'MIT')
+depends=('gcc-libs')
+makedepends=('git' 'rust' 'cmake')
+options=('!lto')
+_commit='aa6988c51c372074222e056e8f7fc8b332272b4e'
+source=("$pkgname::git+$url.git#commit=$_commit")
+md5sums=('SKIP')
+
+prepare() {
+  cd "$pkgname"
+
+  # download dependencies
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+	cd "$pkgname"
+
+	cargo build --release --frozen
+}
+
+check() {
+	cd "$pkgname"
+
+	cargo test --frozen
+}
+
+package() {
+	cd "$pkgname"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" target/release/hck
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+
+  # licenses
+	install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE-MIT UNLICENSE
+}