[arch-commits] Commit in (4 files)

[George Rawlinson]

    Date: Tuesday, April 12, 2022 @ 09:56:45
  Author: grawlinson
Revision: 1185943

addpkg: python-minio 7.1.6-2

Added:
  python-minio/
  python-minio/repos/
  python-minio/trunk/
  python-minio/trunk/PKGBUILD

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Added: python-minio/trunk/PKGBUILD
===================================================================
--- python-minio/trunk/PKGBUILD	                        (rev 0)
+++ python-minio/trunk/PKGBUILD	2022-04-12 09:56:45 UTC (rev 1185943)
@@ -0,0 +1,58 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+
+pkgname=python-minio
+pkgver=7.1.6
+pkgrel=2
+pkgdesc='MinIO Python Library for Amazon S3 Compatible Cloud Storage'
+arch=('any')
+url='https://github.com/minio/minio-py'
+license=('Apache')
+depends=(
+  'python'
+  'python-certifi'
+  'python-urllib3'
+)
+makedepends=(
+  'git'
+  'python-setuptools'
+)
+checkdepends=(
+  'minio'
+  'python-pytest'
+  'python-mock'
+)
+_commit='e8b0d1b9cd0bce5152ebf504717d4505b344547d'
+source=("$pkgname::git+$url.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags
+}
+
+prepare() {
+  cd "$pkgname"
+
+  ln -sf /usr/bin/minio tests/functional/minio
+}
+
+build() {
+  cd "$pkgname"
+
+  python setup.py build
+}
+
+check() {
+  cd "$pkgname"
+
+  python -m pytest
+
+  ./run_functional_tests.sh
+}
+
+package() {
+  cd "$pkgname"
+
+  python setup.py install --root="$pkgdir" --optimize=1
+}