[arch-commits] Commit in python-hachoir/repos (community-any community-any/PKGBUILD)

[George Rawlinson]

    Date: Wednesday, April 13, 2022 @ 07:16:44
  Author: grawlinson
Revision: 1186022

archrelease: copy trunk to community-any

Added:
  python-hachoir/repos/community-any/
  python-hachoir/repos/community-any/PKGBUILD
    (from rev 1186021, python-hachoir/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: python-hachoir/repos/community-any/PKGBUILD (from rev 1186021, python-hachoir/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2022-04-13 07:16:44 UTC (rev 1186022)
@@ -0,0 +1,48 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Luis Martinez <luis dot martinez at tuta dot io>
+# Contributor: Michal Wojdyla < micwoj9292 at gmail dot com >
+# Contributor: arno <apithon.AT.free.DOT.fr>
+# Contributor: Pierre Bourdon <delroth at gmail.com>
+# Contributor: ianux <ianux AT free DOT fr>
+
+pkgname=python-hachoir
+pkgver=3.1.3
+pkgrel=1
+pkgdesc='A Python library to view and edit a binary stream field by field'
+arch=('any')
+url='https://hachoir.readthedocs.io/'
+license=('GPL')
+depends=(
+  'python'
+  'python-urwid'
+  'python-wxpython'
+  'python-darkdetect'
+)
+makedepends=('git' 'python-setuptools')
+_commit='a41e1df9ead5f6df30d616623e26b0537963ce87'
+source=("$pkgname::git+https://github.com/vstinner/hachoir.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags
+}
+
+build() {
+  cd "$pkgname"
+
+  python setup.py build
+}
+
+check() {
+  cd "$pkgname"
+
+  python runtests.py
+}
+
+package() {
+  cd "$pkgname"
+
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}