[arch-commits] Commit in choose/trunk (PKGBUILD)

[George Rawlinson]

    Date: Wednesday, April 13, 2022 @ 08:07:40
  Author: grawlinson
Revision: 1186027

addpkg: choose 1.3.3-2

Added:
  choose/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Added: PKGBUILD
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-04-13 08:07:40 UTC (rev 1186027)
@@ -0,0 +1,51 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Filipe Nascimento <flipee at tuta dot io>
+
+pkgname=choose
+pkgver=1.3.3
+pkgrel=2
+pkgdesc='A human-friendly and fast alternative to cut and (sometimes) awk'
+arch=('x86_64')
+url="https://github.com/theryangeary/choose"
+license=('GPL3')
+depends=('gcc-libs')
+makedepends=('git' 'rust')
+checkdepends=('diffutils')
+options=('!lto')
+_commit='cd71501b72532e7680eed368543654d817747614'
+source=("$pkgname::git+$url.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+prepare() {
+  cd "$pkgname"
+
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$pkgname"
+
+  cargo build --frozen --release
+}
+
+check() {
+  cd "$pkgname"
+
+  cargo test --frozen --release
+
+  ./test/e2e_test.sh
+}
+
+package() {
+  cd "$pkgname"
+
+  install -vDm755 -t "$pkgdir/usr/bin" target/release/choose
+
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" readme.md
+}