[arch-commits] Commit in (4 files)

George Rawlinson grawlinson at gemini.archlinux.org
Wed Apr 13 08:58:40 UTC 2022


    Date: Wednesday, April 13, 2022 @ 08:58:40
  Author: grawlinson
Revision: 1186030

addpkg: angle-grinder 0.18.0-2

Added:
  angle-grinder/
  angle-grinder/repos/
  angle-grinder/trunk/
  angle-grinder/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: angle-grinder/trunk/PKGBUILD
===================================================================
--- angle-grinder/trunk/PKGBUILD	                        (rev 0)
+++ angle-grinder/trunk/PKGBUILD	2022-04-13 08:58:40 UTC (rev 1186030)
@@ -0,0 +1,52 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+
+pkgname=angle-grinder
+pkgver=0.18.0
+pkgrel=2
+pkgdesc="Slice and dice logs on the command line"
+arch=('x86_64')
+url='https://github.com/rcoh/angle-grinder'
+license=('MIT')
+depends=('gcc-libs')
+makedepends=('git' 'rust')
+options=('!lto')
+_commit='ef6187aaa9ff7a2940d840cd320a7cd428fd617d'
+source=("$pkgname::git+$url.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+prepare() {
+  cd "$pkgname"
+
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$pkgname"
+
+  cargo build --frozen --release
+}
+
+check() {
+  cd "$pkgname"
+
+  cargo test --frozen --release
+}
+
+package() {
+  cd "$pkgname"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" target/release/agrind
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}



More information about the arch-commits mailing list