[arch-commits] Commit in (baresip baresip/repos baresip/trunk baresip/trunk/PKGBUILD)
Alexander Epaneshnikov
alex19ep at gemini.archlinux.org
Thu Apr 14 11:13:15 UTC 2022
Date: Thursday, April 14, 2022 @ 11:13:15
Author: alex19ep
Revision: 1186196
add baresip
Added:
baresip/
baresip/repos/
baresip/trunk/
baresip/trunk/PKGBUILD
----------+
PKGBUILD | 56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 56 insertions(+)
Added: baresip/trunk/PKGBUILD
===================================================================
--- baresip/trunk/PKGBUILD (rev 0)
+++ baresip/trunk/PKGBUILD 2022-04-14 11:13:15 UTC (rev 1186196)
@@ -0,0 +1,56 @@
+# Maintainer: Alexander Epaneshnikov <alex19ep at archlinux.org>
+# Contributor: Andrew Sun <adsun701 at gmail dot com>
+# Contributor: Dmitrij D. Czarkoff <czarkoff at gmail dot com>
+
+pkgname=baresip
+pkgver=2.0.2
+pkgrel=1
+pkgdesc="portable and modular SIP User-Agent with audio and video support"
+arch=('x86_64')
+url="http://www.creytiv.com/baresip.html"
+license=('BSD')
+depends=(libre.so librem.so openssl)
+optdepends=('libfdk-aac: AAC audio codec'
+ 'alsa-lib: ALSA audio driver'
+ 'opencore-amr: Adaptive Multi-Rate (AMR) audio codec'
+ 'aom: (av1 module}'
+ 'codec2: CODEC2 low-bitrate speech audio codec'
+ 'ffmpeg: (avcodec, avformat, h265 modules)'
+ 'gsm: (gsm module)'
+ 'gst-plugins-bad: (gst1, gst_video1 modules)'
+ 'gst-plugins-base: (gst1, gst_video1 modules)'
+ 'gst-plugins-good: (gst1, gst_video1 modules)'
+ 'gst-plugins-ugly: (gst1, gst_video1 modules)'
+ 'gtk3: gtk+ user interface'
+ 'jack2: JACK Audio Connection Kit audio driver'
+ 'lame: MPA audio codec'
+ 'libvpx: (vpx module)'
+ 'libsndfile: (sndfile module)'
+ 'libpng: Snapshot video module'
+ 'libpulse: Pulseaudio audio driver'
+ 'libx11: (x11, x11grab modules)'
+ 'mpg123: (rst module)'
+ 'opus: (opus module)'
+ 'portaudio: Portaudio audio driver'
+ 'sdl2: (sdl2 module)'
+ 'spandsp: (g722, g726,plc modules)'
+ 'speexdsp: (speex_aec, speex_pp modules)'
+ 'sndio: sndio audio driver'
+ 'v4l-utils: (v4l2 module)')
+makedepends=(${optdepends[@]/%:*/} python)
+source=("${pkgname}-${pkgver}.tar.gz"::"https://github.com/baresip/baresip/archive/v${pkgver}.tar.gz")
+sha256sums=('f1c48c336ca7300971619358f532367c7dabfc6e16b2b2bfc99646ed50271d93')
+
+build() {
+ cd ${pkgname}-${pkgver}
+ export LFLAGS=$LDFLAGS
+ make RELEASE=1 V=1 USE_GST= USE_GST_VIDEO= DESTDIR="/usr" PREFIX="/usr"
+}
+
+package() {
+ cd ${pkgname}-${pkgver}
+ export LFLAGS=$LDFLAGS
+ make RELEASE=1 USE_GST= USE_GST_VIDEO= PREFIX="/usr" \
+ DESTDIR="$pkgdir/" install
+ install -vDm644 docs/COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
+}
More information about the arch-commits
mailing list