[arch-commits] Commit in nodejs-lts-gallium/repos (2 files)

[Felix Yan]

    Date: Thursday, April 14, 2022 @ 14:43:17
  Author: felixonmars
Revision: 1186229

archrelease: copy trunk to community-staging-x86_64

Added:
  nodejs-lts-gallium/repos/community-staging-x86_64/
  nodejs-lts-gallium/repos/community-staging-x86_64/PKGBUILD
    (from rev 1186228, nodejs-lts-gallium/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: nodejs-lts-gallium/repos/community-staging-x86_64/PKGBUILD (from rev 1186228, nodejs-lts-gallium/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-04-14 14:43:17 UTC (rev 1186229)
@@ -0,0 +1,58 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=nodejs-lts-gallium
+pkgver=16.14.2
+pkgrel=2
+pkgdesc="Evented I/O for V8 javascript (LTS release: Gallium)"
+arch=(x86_64)
+url="https://nodejs.org/"
+license=(MIT)
+depends=(openssl zlib icu libuv c-ares brotli libnghttp2) # http-parser
+makedepends=(python procps-ng)
+optdepends=('npm: nodejs package manager')
+options=(!lto)
+provides=("nodejs=$pkgver")
+conflicts=(nodejs)
+source=(${url}/dist/v${pkgver}/node-v${pkgver}.tar.xz)
+# https://nodejs.org/download/release/latest-gallium/SHASUMS256.txt.asc
+sha256sums=(e922e215cc68eb5f94d33e8a0b61e2c863b7731cc8600ab955d3822da90ff8d1)
+validpgpkeys=(C4F0DFFF4E8C1A8236409D08E73BC641CC11F4C8  # Myles Borins <mylesborins at google.com>
+              77984A986EBC2AA786BC0F66B01FBB92821C587A  # Gibson Fahnestock <gibfahn at gmail.com>
+              B9AE9905FFD7803F25714661B63B535A4C206CA9  # Evan Lucas <evanlucas at me.com>
+              DD8F2338BAE7501E3DD5AC78C273792F7D83545D  # Rod Vagg <rod at vagg.org>
+              B9E2F5981AA6E0CD28160D9FF13993A75599653C  # Shelley Vohr <shelley.vohr at gmail.com>
+              4ED778F539E3634C779C87C6D7062848A1AB005C  # Beth Griggs <Bethany.Griggs at uk.ibm.com>
+              C82FA3AE1CBEDC6BE46B9360C43CEC45C17AB93C  # Richard Lau <rlau at redhat.com>
+              74F12602B6F1C4E913FAA37AD3A89613643B6201) # Danielle Adams <adamzdanielle at gmail.com>
+
+build() {
+  cd node-v${pkgver}
+
+  ./configure \
+    --prefix=/usr \
+    --with-intl=system-icu \
+    --without-npm \
+    --shared-openssl \
+    --shared-zlib \
+    --shared-libuv \
+    --experimental-http-parser \
+    --shared-cares \
+    --shared-brotli \
+    --shared-nghttp2
+    # --shared-v8
+    # --shared-http-parser
+
+  make
+}
+
+check() {
+  cd node-v${pkgver}
+  make test-only
+}
+
+package() {
+  cd node-v${pkgver}
+  make DESTDIR="${pkgdir}" install
+  install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}