[arch-commits] Commit in arch-release-promotion/trunk (PKGBUILD)

[David Runge]

    Date: Thursday, April 14, 2022 @ 17:26:52
  Author: dvzrv
Revision: 1186246

upgpkg: arch-release-promotion 0.2.2-1: Upgrade to 0.2.2.

Remove unneeded quotes and curly braces.
Switch to PEP517.

Modified:
  arch-release-promotion/trunk/PKGBUILD

----------+
 PKGBUILD |   53 +++++++++++++++++++++++------------------------------
 1 file changed, 23 insertions(+), 30 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-04-14 16:42:15 UTC (rev 1186245)
+++ PKGBUILD	2022-04-14 17:26:52 UTC (rev 1186246)
@@ -1,44 +1,37 @@
 # Maintainer: David Runge <dvzrv at archlinux.org>
 
 pkgname=arch-release-promotion
-pkgver=0.2.1
-pkgrel=2
+pkgver=0.2.2
+pkgrel=1
 pkgdesc="Promote official releases with signatures and additional artifacts"
-arch=('any')
+arch=(any)
 url="https://gitlab.archlinux.org/archlinux/arch-release-promotion"
-license=('GPL3')
-depends=('python-dotenv' 'python-email-validator' 'python-gitlab'
-'python-orjson' 'python-prometheus_client' 'python-pydantic' 'python-pyxdg'
-'python-toml' 'python-torrentool')
-makedepends=('python-setuptools')
-checkdepends=('python-pytest')
-backup=("etc/${pkgname}/projects.toml")
-source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/${pkgname}/${pkgname}-${pkgver}.tar.gz")
-sha256sums=('5a67197daa9f35f1aa9bc957f577281b519505600d93895bb3fe426ad1a24dcc')
-b2sums=('4f4da3a74655c25003b8b9243cb1d2a521cded8e6109cc2667b108475e85e529acb5dabd10cced8ef96c2e515be68837922896ca52b7fc7a1bf4d5e722527e38')
+license=(GPL3)
+depends=(python-dotenv python-email-validator python-gitlab python-orjson
+python-prometheus_client python-pydantic python-pyxdg python-toml
+python-torrentool)
+makedepends=(python-build python-installer python-poetry python-wheel)
+checkdepends=(python-pytest)
+backup=(etc/$pkgname/projects.toml)
+source=(https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$pkgname-$pkgver.tar.gz)
+sha256sums=('cfcc473d0805239ed76a8a90d489316af2d64717275827c1cc7b651c4ddfa718')
+b2sums=('2a03da131001897ea8cbed6c0075e3f2e01d40a70e9a4760c4fa65f285b872da8e2b417a7f3f906ca6fab5f220db6a6b6fd6c901b6392763580d5ac32a560ae9')
 
-prepare() {
-  cd "$pkgname-$pkgver"
-}
-
 build() {
-  cd "$pkgname-$pkgver"
-  python setup.py build
+  cd $pkgname-$pkgver
+  python -m build --wheel --no-isolation
 }
 
 check() {
-  cd "$pkgname-$pkgver"
-  export PYTHONPATH="build:${PYTHONPATH}"
-  pytest -v
+  cd $pkgname-$pkgver
+  pytest -vv
 }
 
 package() {
-  cd "$pkgname-$pkgver"
-  python setup.py install --skip-build \
-                          --optimize=1 \
-                          --root="${pkgdir}"
-  install -vDm 644 {examples/example.toml,README.rst} -t "${pkgdir}/usr/share/doc/${pkgname}"
-  install -vDm 644 examples/projects.toml -t "${pkgdir}/etc/${pkgname}"
-  install -vDm 644 examples/systemd/*.{service,timer} -t "${pkgdir}/usr/lib/systemd/system/"
-  install -vDm 644 examples/sysusers.d/*.conf -t "${pkgdir}/usr/lib/sysusers.d/"
+  cd $pkgname-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -vDm 644 {examples/example.toml,README.rst} -t "$pkgdir/usr/share/doc/$pkgname/"
+  install -vDm 644 examples/projects.toml -t "$pkgdir/etc/$pkgname/"
+  install -vDm 644 examples/systemd/*.{service,timer} -t "$pkgdir/usr/lib/systemd/system/"
+  install -vDm 644 examples/sysusers.d/*.conf -t "$pkgdir/usr/lib/sysusers.d/"
 }