[arch-commits] Commit in enchant/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Evangelos Foutras
foutrelis at gemini.archlinux.org
Thu Apr 14 18:33:51 UTC 2022
Date: Thursday, April 14, 2022 @ 18:33:51
Author: foutrelis
Revision: 442564
archrelease: copy trunk to staging-x86_64
Added:
enchant/repos/staging-x86_64/
enchant/repos/staging-x86_64/PKGBUILD
(from rev 442563, enchant/trunk/PKGBUILD)
----------+
PKGBUILD | 46 ++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 46 insertions(+)
Copied: enchant/repos/staging-x86_64/PKGBUILD (from rev 442563, enchant/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2022-04-14 18:33:51 UTC (rev 442564)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at gmail.com>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: dorphell <dorphell at archlinux.org>
+
+pkgname=enchant
+pkgver=2.3.2
+pkgrel=2
+pkgdesc="A wrapper library for generic spell checking"
+arch=('x86_64')
+url="https://abiword.github.io/enchant/"
+license=('LGPL')
+depends=('glib2')
+makedepends=('aspell' 'hunspell' 'hspell' 'nuspell' 'libvoikko')
+checkdepends=('unittestpp')
+optdepends=('aspell: for aspell based spell checking support'
+ 'hunspell: for hunspell based spell checking support'
+ 'libvoikko: for libvoikko based spell checking support'
+ 'hspell: for hspell based spell checking support'
+ 'nuspell: for nuspell based spell checking support')
+provides=('libenchant-2.so') # enchant_voikko.so enchant_nuspell.so enchant_hunspell.so enchant_hspell.so enchant_aspell.so)
+source=("https://github.com/AbiWord/enchant/releases/download/v$pkgver/enchant-$pkgver.tar.gz")
+sha512sums=('886635bb55c5f0c774445e4a0f14d39e2d08eeb964257037062c2e97c2cf3348be8c631ff5e7a13144936127761964bdc60ff1e0dd6f63b292a655626f91ef62')
+
+prepare() {
+ cd $pkgname-$pkgver
+ autoreconf -vfi
+}
+
+build() {
+ cd $pkgname-$pkgver
+ ./configure --prefix=/usr \
+ --disable-static \
+ --enable-relocatable
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+check() {
+ cd $pkgname-$pkgver
+ make check
+}
+
+package() {
+ cd $pkgname-$pkgver
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list