[arch-commits] Commit in webkit2gtk/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Thursday, April 14, 2022 @ 19:27:49
  Author: felixonmars
Revision: 442586

archrelease: copy trunk to staging-x86_64

Added:
  webkit2gtk/repos/staging-x86_64/
  webkit2gtk/repos/staging-x86_64/PKGBUILD
    (from rev 442585, webkit2gtk/trunk/PKGBUILD)

----------+
 PKGBUILD |   71 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)

Copied: webkit2gtk/repos/staging-x86_64/PKGBUILD (from rev 442585, webkit2gtk/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-04-14 19:27:49 UTC (rev 442586)
@@ -0,0 +1,71 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Eric Bélanger <eric at archlinux.org>
+
+pkgname=webkit2gtk
+pkgver=2.36.0
+pkgrel=3
+pkgdesc="Web content engine for GTK"
+url="https://webkitgtk.org"
+arch=(x86_64)
+license=(custom)
+depends=(cairo fontconfig freetype2 libgcrypt glib2 gtk3 harfbuzz harfbuzz-icu
+         icu libjpeg libsoup libxml2 zlib libpng sqlite atk libwebp at-spi2-core
+         libegl libgl libgles libwpe wpebackend-fdo libxslt libsecret libtasn1
+         enchant libx11 libxext libice libxt wayland libnotify hyphen openjpeg2
+         woff2 libsystemd bubblewrap libseccomp xdg-dbus-proxy gstreamer
+         gst-plugins-base-libs libmanette)
+makedepends=(cmake ninja gtk-doc python ruby gobject-introspection
+             wayland-protocols systemd gst-plugins-bad gperf)
+optdepends=('geoclue: Geolocation support'
+            'gst-plugins-good: media decoding'
+            'gst-plugins-bad: media decoding'
+            'gst-libav: nonfree media decoding')
+options=(debug)
+source=($url/releases/webkitgtk-$pkgver.tar.xz{,.asc})
+sha256sums=('b877cca1f105235f5dd57c7ac2b2c2be3c6b691ff444f93925c7254cf156c64d'
+            'SKIP')
+validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3'  # Carlos Garcia Campos <cgarcia at igalia.com>
+              '5AA3BC334FD7E3369E7C77B291C559DBE4C9123B') # Adrián Pérez de Castro <aperez at igalia.com>
+
+prepare() {
+  cd webkitgtk-$pkgver
+}
+
+build() {
+  # Produce minimal debug info: 4.3 GB of debug data makes the
+  # build too slow and is too much to package for debuginfod
+  CFLAGS+=' -g1'
+  CXXFLAGS+=' -g1'
+
+  cmake -S webkitgtk-$pkgver -B build -G Ninja \
+    -DPORT=GTK \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DCMAKE_SKIP_RPATH=ON \
+    -DUSE_SOUP2=ON \
+    -DENABLE_GTKDOC=OFF \
+    -DENABLE_MINIBROWSER=ON
+  cmake --build build
+}
+
+package() {
+  depends+=(libwpe-1.0.so libWPEBackend-fdo-1.0.so)
+  provides+=(libjavascriptcoregtk-4.0.so libwebkit2gtk-4.0.so)
+
+  DESTDIR="$pkgdir" cmake --install build
+
+  rm -r "$pkgdir/usr/bin"
+
+  cd webkitgtk-$pkgver
+  find Source -name 'COPYING*' -or -name 'LICENSE*' -print0 | sort -z |
+    while IFS= read -d $'\0' -r _f; do
+      echo "### $_f ###"
+      cat "$_f"
+      echo
+    done |
+    install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set sw=2 et: