[arch-commits] Commit in (jo jo/repos jo/trunk jo/trunk/PKGBUILD)

[George Rawlinson]

    Date: Thursday, April 14, 2022 @ 21:58:22
  Author: grawlinson
Revision: 1186286

addpkg: jo 1.6-2

Added:
  jo/
  jo/repos/
  jo/trunk/
  jo/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: jo/trunk/PKGBUILD
===================================================================
--- jo/trunk/PKGBUILD	                        (rev 0)
+++ jo/trunk/PKGBUILD	2022-04-14 21:58:22 UTC (rev 1186286)
@@ -0,0 +1,50 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Sebastian LaVine <mail at smlavine.com>
+# Contributor: Lance Chen <cyen0312 at gmail.com>
+
+pkgname=jo
+pkgver=1.6
+pkgrel=2
+pkgdesc='JSON output from a shell'
+arch=('x86_64')
+url='https://github.com/jpmens/jo'
+license=('GPL2')
+depends=('glibc')
+makedepends=('git' 'pandoc')
+_commit='6962bca178a6778328d1126ff762120305bb4327'
+source=("$pkgname::git+$url.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cd "$pkgname"
+
+  autoreconf -vfi
+
+  ./configure \
+    --prefix=/usr \
+    bashcompdir=/usr/share/bash-completion/completions
+
+  make all
+}
+
+check() {
+  cd "$pkgname"
+
+  make -k check
+}
+
+package() {
+  cd "$pkgname"
+
+  make DESTDIR="$pkgdir" install
+
+  # TODO: patch in autotools, or just leave as is ...
+  cd "$pkgdir/usr/share/bash-completion/completions"
+  mv jo.bash jo
+}