[arch-commits] Commit in tesseract/repos (2 files)

[Felix Yan]

    Date: Thursday, April 14, 2022 @ 22:51:29
  Author: felixonmars
Revision: 1186369

archrelease: copy trunk to community-staging-x86_64

Added:
  tesseract/repos/community-staging-x86_64/
  tesseract/repos/community-staging-x86_64/PKGBUILD
    (from rev 1186368, tesseract/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: tesseract/repos/community-staging-x86_64/PKGBUILD (from rev 1186368, tesseract/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-04-14 22:51:29 UTC (rev 1186369)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Andreas Hauser <andy-aur at splashground.de>
+
+_langs=(afr amh ara asm aze aze_cyrl bel ben bod bos bre bul cat ceb ces
+    chi_sim chi_tra chr cos cym dan dan_frak deu deu_frak div dzo ell eng enm epo
+    equ est eus fao fas fil fin fra frk frm fry gla gle glg grc guj hat heb
+    hin hrv hun hye iku ind isl ita ita_old jav jpn jpn_vert kan kat kat_old kaz khm
+    kir kmr kor kor_vert lao lat lav lit ltz mal mar mkd mlt mon mri msa
+    mya nep nld nor oci ori osd pan pol por pus que ron rus san sin slk
+    slk_frak slv snd spa spa_old sqi srp srp_latn sun swa swe syr tam tat
+    tel tgk tgl tha tir ton tur uig ukr urd uzb uzb_cyrl vie yid yor)
+
+pkgname=tesseract
+pkgver=5.1.0
+pkgrel=2
+pkgdesc='An OCR program'
+arch=(x86_64)
+url="https://github.com/tesseract-ocr/tesseract"
+license=('APACHE')
+depends=(libpng libtiff libjpeg-turbo zlib giflib gcc-libs curl libarchive leptonica)
+makedepends=(icu cairo pango asciidoc)
+optdepends=(icu cairo pango
+            "${_langs[@]/#/tesseract-data-}")
+provides=(libtesseract.so)
+source=("$url/archive/$pkgver/$pkgname-$pkgver.tar.gz")
+sha256sums=('fdec8528d5a0ecc28ab5fff985e0b8ced60726f6ef33f54126f2868e323d4bd2')
+
+build() {
+  cd "$srcdir"/$pkgname-${pkgver}
+  [ -x configure ] || ./autogen.sh
+  [ -f Makefile ] || ./configure --prefix=/usr
+  make
+  make training
+}
+
+package() {
+  # The virtual package 'tessdata' is provided by all of the packaged language
+  # packs. All languages are listed as optdepends but at least one is required
+  # for basic functionality. These are in package() so they do not turn up in
+  # makedepends=() where they would be circular.
+  depends+=(tessdata tesseract-data-osd)
+  cd "$srcdir"/$pkgname-${pkgver}
+  make DESTDIR="$pkgdir" install
+  make DESTDIR="$pkgdir" training-install
+}