[arch-commits] Commit in wpewebkit/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Felix Yan
felixonmars at gemini.archlinux.org
Thu Apr 14 23:04:34 UTC 2022
Date: Thursday, April 14, 2022 @ 23:04:34
Author: felixonmars
Revision: 442630
archrelease: copy trunk to staging-x86_64
Added:
wpewebkit/repos/staging-x86_64/
wpewebkit/repos/staging-x86_64/PKGBUILD
(from rev 442629, wpewebkit/trunk/PKGBUILD)
----------+
PKGBUILD | 67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 67 insertions(+)
Copied: wpewebkit/repos/staging-x86_64/PKGBUILD (from rev 442629, wpewebkit/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2022-04-14 23:04:34 UTC (rev 442630)
@@ -0,0 +1,67 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=wpewebkit
+pkgver=2.36.0
+pkgrel=3
+pkgdesc="Web content engine for embedded devices"
+url="https://wpewebkit.org"
+arch=(x86_64)
+license=(custom)
+depends=(cairo fontconfig freetype2 glib2 harfbuzz harfbuzz-icu icu libjpeg
+ libepoxy libgcrypt libsoup3 libxml2 zlib libpng sqlite libwebp libwpe
+ atk at-spi2-atk openjpeg2 woff2 libtasn1 libxslt libsystemd bubblewrap
+ libseccomp xdg-dbus-proxy gstreamer gst-plugins-base-libs libxkbcommon
+ wayland wpebackend-fdo)
+makedepends=(cmake ninja gtk-doc python ruby systemd gst-plugins-bad gperf
+ wayland-protocols)
+optdepends=('geoclue: Geolocation support'
+ 'gst-plugins-good: media decoding'
+ 'gst-plugins-bad: media decoding'
+ 'gst-libav: nonfree media decoding')
+options=(debug)
+source=($url/releases/$pkgname-$pkgver.tar.xz{,.asc})
+sha256sums=('096aa9f87d9bfbfc80f558388a86721cdcc508b42ddef10bd270aec9aee96d5a'
+ 'SKIP')
+validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3' # Carlos Garcia Campos <cgarcia at igalia.com>
+ '5AA3BC334FD7E3369E7C77B291C559DBE4C9123B') # Adrián Pérez de Castro <aperez at igalia.com>
+
+prepare() {
+ cd $pkgname-$pkgver
+}
+
+build() {
+ # Produce minimal debug info: 4.3 GB of debug data makes the
+ # build too slow and is too much to package for debuginfod
+ CFLAGS+=' -g1'
+ CXXFLAGS+=' -g1'
+
+ cmake -S $pkgname-$pkgver -B build -G Ninja \
+ -DPORT=WPE \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DCMAKE_INSTALL_LIBEXECDIR=lib \
+ -DCMAKE_SKIP_RPATH=ON \
+ -DUSE_SOUP2=OFF \
+ -DENABLE_GTKDOC=ON \
+ -DENABLE_MINIBROWSER=ON
+ cmake --build build
+}
+
+package() {
+ depends+=(libwpe-1.0.so libWPEBackend-fdo-1.0.so)
+ provides+=(libWPEWebKit-1.1.so)
+
+ DESTDIR="$pkgdir" cmake --install build
+
+ cd $pkgname-$pkgver
+ find Source -name 'COPYING*' -or -name 'LICENSE*' -print0 | sort -z |
+ while IFS= read -d $'\0' -r _f; do
+ echo "### $_f ###"
+ cat "$_f"
+ echo
+ done |
+ install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set sw=2 et:
More information about the arch-commits
mailing list