[arch-commits] Commit in tepl/repos (2 files)
Felix Yan
felixonmars at gemini.archlinux.org
Thu Apr 14 23:18:35 UTC 2022
Date: Thursday, April 14, 2022 @ 23:18:35
Author: felixonmars
Revision: 1186390
archrelease: copy trunk to community-staging-x86_64
Added:
tepl/repos/community-staging-x86_64/
tepl/repos/community-staging-x86_64/PKGBUILD
(from rev 1186388, tepl/trunk/PKGBUILD)
----------+
PKGBUILD | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
Copied: tepl/repos/community-staging-x86_64/PKGBUILD (from rev 1186388, tepl/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-04-14 23:18:35 UTC (rev 1186390)
@@ -0,0 +1,54 @@
+# Maintainer:
+# Contributor: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Tobias Bohrmann (PlainTextField) <honeypot.carbage at aechelon.de>
+
+pkgname=tepl
+pkgver=6.00.0
+pkgrel=5
+_commit=51b15258e130d2b5134f6cd5ff7f91c75e0a482a # tags/6.0.0.0^0
+pkgdesc="Library that eases the development of GtkSourceView-based text editors and IDEs"
+url="https://gitlab.gnome.org/Archive/tepl"
+arch=(x86_64)
+license=(LGPL3)
+depends=(amtk
+ gtksourceview4
+ uchardet)
+makedepends=(gobject-introspection
+ git
+ gtk-doc
+ meson
+ vala)
+checkdepends=(xorg-server-xvfb)
+source=("git+https://gitlab.gnome.org/Archive/tepl.git#commit=$_commit")
+sha256sums=('SKIP')
+
+prepare() {
+ cd $pkgname
+ git tag -f 6.00.0 '6.0.0.0^0'; git tag -d 6.0.0.0 # Fixup tag
+}
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+build() {
+ arch-meson $pkgname build -D gtk_doc=true
+ meson compile -C build
+}
+
+check() {
+ xvfb-run -s '-screen 0 1920x1080x24 -nolisten local' \
+ meson test -C build --print-errorlogs
+}
+
+package() {
+ depends+=(libamtk-5.so
+ libgtksourceview-4.so
+ libg{d,t}k-3.so
+ libg{lib,object,io}-2.0.so)
+ provides+=("libtepl-${pkgver%%.*}.so")
+ DESTDIR="$pkgdir" meson install -C build
+}
More information about the arch-commits
mailing list