[arch-commits] Commit in jc/repos (community-any community-any/PKGBUILD)

[George Rawlinson]

    Date: Friday, April 15, 2022 @ 04:26:00
  Author: grawlinson
Revision: 1186442

archrelease: copy trunk to community-any

Added:
  jc/repos/community-any/
  jc/repos/community-any/PKGBUILD
    (from rev 1186441, jc/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: jc/repos/community-any/PKGBUILD (from rev 1186441, jc/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2022-04-15 04:26:00 UTC (rev 1186442)
@@ -0,0 +1,54 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Jameson Pugh <imntreal at gmail.com>
+
+pkgname=jc
+pkgver=1.18.6
+pkgrel=2
+pkgdesc='Converts the output of popular command-line tools and file-types to JSON'
+arch=('any')
+url='https://github.com/kellyjonbrazil/jc'
+license=('MIT')
+depends=(
+  'python'
+  'python-pygments'
+  'python-ruamel-yaml'
+  'python-xmltodict'
+)
+makedepends=('git' 'python-setuptools')
+_commit='e05be3f08beae1b600fc55a3a7b4e28163e15bc0'
+source=("$pkgname::git+$url.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+build(){
+  cd "$pkgname"
+
+  python setup.py build
+}
+
+check() {
+  cd "$pkgname"
+
+  python -m unittest -v
+}
+
+package() {
+  cd "$pkgname"
+
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md EXAMPLES.md
+  cp -vr docs "$pkgdir/usr/share/doc/$pkgname"
+
+  # man page
+  install -vDm644 -t "$pkgdir/usr/share/man/man1" man/jc.1
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.md
+}