[arch-commits] Commit in python-pywlroots/repos/community-x86_64 (PKGBUILD PKGBUILD)

[David Runge]

    Date: Friday, April 15, 2022 @ 10:21:16
  Author: dvzrv
Revision: 1186473

archrelease: copy trunk to community-x86_64

Added:
  python-pywlroots/repos/community-x86_64/PKGBUILD
    (from rev 1186472, python-pywlroots/trunk/PKGBUILD)
Deleted:
  python-pywlroots/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   85 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 43 insertions(+), 42 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-04-15 10:21:05 UTC (rev 1186472)
+++ PKGBUILD	2022-04-15 10:21:16 UTC (rev 1186473)
@@ -1,42 +0,0 @@
-# Maintainer: David Runge <dvzrv at archlinux.org>
-
-_name=pywlroots
-pkgname=python-pywlroots
-pkgver=0.15.11
-pkgrel=1
-pkgdesc="Python binding to the wlroots library using cffi"
-arch=(x86_64)
-url="https://github.com/flacjacket/pywlroots"
-license=(custom:UIUC)
-depends=(glibc python-cffi python-pywayland python-xkbcommon wlroots
-libwlroots.so)
-makedepends=(python-setuptools)
-checkdepends=(python-pytest)
-provides=(pywlroots)
-conflicts=(pywlroots)
-replaces=(pywlroots)
-options=(debug)
-source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
-sha512sums=('20d34113ed81843f0797541d736e4557882c647a5f2a1351f064d19e16d418468553430d4dfc9f90ff3d898099447123148651b2b226da972fb336b970f92cbb')
-b2sums=('7b815b9580ec9920f2f0dee64b0432f38646b1dfb8547d3619792e39e20445bb9d4e7bbe7ed55870bb7932a5003a64b2bb684abfb4ce224bbc8b1fba7e3a98b7')
-
-build() {
-  cd $_name-$pkgver
-  python wlroots/ffi_build.py
-  python setup.py build
-}
-
-check() {
-  local _py_ver=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
-
-  cd $_name-$pkgver
-  export PYTHONPATH="build/lib.linux-$CARCH-$_py_ver:$PYTHONPATH"
-  pytest -v
-}
-
-package() {
-  cd $_name-$pkgver
-  python setup.py install --optimize=1 --root="$pkgdir"
-  install -vDm 644 README.rst -t "$pkgdir/usr/share/doc/$pkgname"
-  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
-}

Copied: python-pywlroots/repos/community-x86_64/PKGBUILD (from rev 1186472, python-pywlroots/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-04-15 10:21:16 UTC (rev 1186473)
@@ -0,0 +1,43 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=pywlroots
+pkgname=python-pywlroots
+pkgver=0.15.12
+pkgrel=1
+pkgdesc="Python binding to the wlroots library using cffi"
+arch=(x86_64)
+url="https://github.com/flacjacket/pywlroots"
+license=(custom:UIUC)
+depends=(glibc python-cffi python-pywayland python-xkbcommon wlroots
+libwlroots.so)
+makedepends=(python-build python-installer python-setuptools python-wheel)
+checkdepends=(python-pytest)
+provides=(pywlroots)
+conflicts=(pywlroots)
+replaces=(pywlroots)
+options=(debug)
+source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
+sha512sums=('bb463bba9ee363c43b004468007c9178620d8901213b2c162e5474f365fc3e84d0f250140dc58d437139321ecd49128d2f2fa820e7e345ae82b01f09c22fd221')
+b2sums=('d1ffc94ac11db4682122f1c17a2549560484f33b0ac08555ced2b9249210c5fe570b9e6adc7050168ca8ad2a131df9d9981c73dd2426cd54c1f8c8ebf22be561')
+
+build() {
+  cd $_name-$pkgver
+  python wlroots/ffi_build.py
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  local _site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
+
+  cd $_name-$pkgver
+  python -m installer --destdir=test_dir dist/*.whl
+  export PYTHONPATH="test_dir/$_site_packages:$PYTHONPATH"
+  pytest -vv
+}
+
+package() {
+  cd $_name-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -vDm 644 README.rst -t "$pkgdir/usr/share/doc/$pkgname"
+  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+}