[arch-commits] Commit in apko/repos (community-x86_64 community-x86_64/PKGBUILD)

[Kpcyrd]

    Date: Saturday, April 16, 2022 @ 14:20:03
  Author: kpcyrd
Revision: 1186663

archrelease: copy trunk to community-x86_64

Added:
  apko/repos/community-x86_64/
  apko/repos/community-x86_64/PKGBUILD
    (from rev 1186662, apko/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: apko/repos/community-x86_64/PKGBUILD (from rev 1186662, apko/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2022-04-16 14:20:03 UTC (rev 1186663)
@@ -0,0 +1,40 @@
+# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
+
+pkgname=apko
+pkgver=0.3.3
+pkgrel=1
+pkgdesc="declarative APK-based container building tool with support for Sigstore signatures"
+url="https://github.com/chainguard-dev/apko"
+arch=('x86_64')
+license=('Apache')
+depends=('apk-tools' 'alpine-keyring')
+makedepends=('go')
+source=("https://github.com/chainguard-dev/apko/archive/v${pkgver}/apko-${pkgver}.tar.gz")
+b2sums=('16db20302fca6a6cbdbfbbd2b996385ab9e4b996f84bcdd82e9d5f28cfb5337ca8e647be7eaff5f08f3be038e1cd346c31b7ad533c36ad50991261059ae83f87')
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  mkdir build
+  CGO_LDFLAGS="${LDFLAGS}" \
+    GOFLAGS="-trimpath -buildmode=pie -mod=readonly" \
+    go build -o build/ -tags -tags=pivkey,pkcs11key ./...
+
+  for i in bash fish zsh; do
+    build/apko completion ${i} > ./apko.${i}
+  done
+}
+
+check() {
+  cd "${pkgname}-${pkgver}"
+  go test ./...
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  install -Dm755 build/apko "${pkgdir}"/usr/bin/apko
+  install -Dm644 apko.bash "${pkgdir}"/usr/share/bash-completion/completions/apko
+  install -Dm644 apko.fish "${pkgdir}"/usr/share/fish/completions/apko.fish
+  install -Dm644 apko.zsh "${pkgdir}"/usr/share/zsh/site-functions/_apko
+}
+
+# vim: ts=2 sw=2 et: