[arch-commits] Commit in fennel/repos (community-any community-any/PKGBUILD)

[George Rawlinson]

    Date: Saturday, April 16, 2022 @ 23:42:26
  Author: grawlinson
Revision: 1186835

archrelease: copy trunk to community-any

Added:
  fennel/repos/community-any/
  fennel/repos/community-any/PKGBUILD
    (from rev 1186834, fennel/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: fennel/repos/community-any/PKGBUILD (from rev 1186834, fennel/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2022-04-16 23:42:26 UTC (rev 1186835)
@@ -0,0 +1,45 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Katie Wolfe <wolfe at katie.host>
+
+pkgname=fennel
+pkgver=1.1.0
+pkgrel=2
+pkgdesc='A Lua Lisp language'
+arch=('any')
+url='https://fennel-lang.org'
+license=('MIT')
+depends=('lua')
+makedepends=('git')
+_commit='21c429235d49b2908c7e46442660b6f22da90efc'
+source=("$pkgname::git+https://git.sr.ht/~technomancy/fennel#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cd "$pkgname"
+
+  make build
+}
+
+check() {
+  cd "$pkgname"
+
+  make test
+}
+
+package() {
+  cd "$pkgname"
+
+  make DESTDIR="$pkgdir" PREFIX=/usr MAN_DIR=/usr/share/man/man1 install
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" *.md
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}