[arch-commits] Commit in (4 files)
Caleb Maclennan
alerque at gemini.archlinux.org
Sun Apr 17 08:37:25 UTC 2022
Date: Sunday, April 17, 2022 @ 08:37:24
Author: alerque
Revision: 1186845
Initial add of lua-cldr, new dependency for sile
Added:
lua-cldr/
lua-cldr/repos/
lua-cldr/trunk/
lua-cldr/trunk/PKGBUILD
----------+
PKGBUILD | 45 +++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 45 insertions(+)
Added: lua-cldr/trunk/PKGBUILD
===================================================================
--- lua-cldr/trunk/PKGBUILD (rev 0)
+++ lua-cldr/trunk/PKGBUILD 2022-04-17 08:37:24 UTC (rev 1186845)
@@ -0,0 +1,45 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+
+_rockname=cldr
+_project=$_rockname-lua
+pkgname=("lua-$_rockname" "lua51-$_rockname" "lua52-$_rockname" "lua53-$_rockname")
+pkgver=0.2.0
+_rockrel=0
+pkgrel=2
+pkgdesc='Lua interface to Unicode CLDR data'
+arch=(any)
+url="https://github.com/alerque/$_project"
+license=(MIT custom:ICU)
+_luadeps=(penlight)
+makedepends=(lua
+ lua51
+ lua52
+ lua53
+ luarocks)
+_archive="$_project-$pkgver"
+source=("$_rockname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha256sums=('9e7ac91fec23fea571d08d5663145842d463d0778967ff6f6fa29cc621647aa9')
+
+_package() {
+ cd "$_archive"
+ depends=("${pkgname%-*}" "${_luadeps[@]/#/${pkgname%-*}-}")
+ luarocks --lua-version="$1" --tree="$pkgdir/usr/" \
+ make --deps-mode=none --no-manifest "$_rockname-dev-$_rockrel.rockspec"
+ install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}
+
+package_lua-cldr() {
+ _package 5.4
+}
+
+package_lua51-cldr() {
+ _package 5.1
+}
+
+package_lua52-cldr() {
+ _package 5.2
+}
+
+package_lua53-cldr() {
+ _package 5.3
+}
More information about the arch-commits
mailing list