[arch-commits] Commit in enchant/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Felix Yan]

    Date: Monday, April 18, 2022 @ 17:08:14
  Author: felixonmars
Revision: 442900

archrelease: copy trunk to testing-x86_64

Added:
  enchant/repos/testing-x86_64/
  enchant/repos/testing-x86_64/PKGBUILD
    (from rev 442899, enchant/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: enchant/repos/testing-x86_64/PKGBUILD (from rev 442899, enchant/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-04-18 17:08:14 UTC (rev 442900)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at gmail.com>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: dorphell <dorphell at archlinux.org>
+
+pkgname=enchant
+pkgver=2.3.3
+pkgrel=1
+pkgdesc="A wrapper library for generic spell checking"
+arch=('x86_64')
+url="https://abiword.github.io/enchant/"
+license=('LGPL')
+depends=('glib2')
+makedepends=('aspell' 'hunspell' 'hspell' 'nuspell' 'libvoikko')
+checkdepends=('unittestpp')
+optdepends=('aspell: for aspell based spell checking support'
+            'hunspell: for hunspell based spell checking support'
+            'libvoikko: for libvoikko based spell checking support'
+            'hspell: for hspell based spell checking support'
+            'nuspell: for nuspell based spell checking support')
+provides=('libenchant-2.so') # enchant_voikko.so enchant_nuspell.so enchant_hunspell.so enchant_hspell.so enchant_aspell.so)
+source=("https://github.com/AbiWord/enchant/releases/download/v$pkgver/enchant-$pkgver.tar.gz")
+sha512sums=('c97764a8f219033b440cbfb820624f54993b19ba1f38b56f20336889304f753c7c513008bb92cd1424bfbf528c2d473f35bef93d9140063612e3a270fd000deb')
+
+prepare() {
+  cd $pkgname-$pkgver
+  autoreconf -vfi
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr \
+    --disable-static \
+    --enable-relocatable
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname-$pkgver
+  make check
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}