[arch-commits] Commit in python-pywayland/repos/community-x86_64 (PKGBUILD PKGBUILD)

[David Runge]

    Date: Tuesday, April 19, 2022 @ 07:41:31
  Author: dvzrv
Revision: 1187071

archrelease: copy trunk to community-x86_64

Added:
  python-pywayland/repos/community-x86_64/PKGBUILD
    (from rev 1187070, python-pywayland/trunk/PKGBUILD)
Deleted:
  python-pywayland/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   79 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 40 insertions(+), 39 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-04-19 07:41:15 UTC (rev 1187070)
+++ PKGBUILD	2022-04-19 07:41:31 UTC (rev 1187071)
@@ -1,39 +0,0 @@
-# Maintainer: David Runge <dvzrv at archlinux.org>
-
-_name=pywayland
-pkgname=python-pywayland
-pkgver=0.4.11
-pkgrel=1
-pkgdesc="Python bindings for the libwayland library"
-arch=(x86_64)
-url="https://github.com/flacjacket/pywayland"
-license=(Apache)
-depends=(python-cffi wayland)
-makedepends=(python-setuptools wayland-protocols)
-checkdepends=(python-pytest)
-source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
-sha512sums=('136d42129559d569f372acb65df354c7dab6cb39b5c5039f40132c4ee62fcd89518843af1333a4a6d669855d3cf5c3064602dc12cc9b7ec8ced84d8e4f48bca0')
-b2sums=('f483b255d074cff977cfa1e235d6ed9492dd077eccc1aba9ebfe629977eb1be2b74f88650ce2e5f990a219ecabb37d1e3d81bd5626fa8a0b532a5d2c970a292b')
-
-build() {
-  cd $_name-$pkgver
-  python pywayland/ffi_build.py
-  python -m pywayland.scanner
-  python setup.py build
-}
-
-check() {
-  local _py_ver="$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')"
-
-  cd $_name-$pkgver
-  mkdir -vp temp
-  export PYTHONPATH="build/lib.linux-$CARCH-$_py_ver:$PYTHONPATH"
-  export XDG_RUNTIME_DIR="$PWD/temp"
-  pytest -v
-}
-
-package() {
-  cd $_name-$pkgver
-  python setup.py install --optimize=1 --root="$pkgdir"
-  install -vDm 644 README.rst -t "$pkgdir/usr/share/doc/$pkgname"
-}

Copied: python-pywayland/repos/community-x86_64/PKGBUILD (from rev 1187070, python-pywayland/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-04-19 07:41:31 UTC (rev 1187071)
@@ -0,0 +1,40 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=pywayland
+pkgname=python-pywayland
+pkgver=0.4.12
+pkgrel=1
+pkgdesc="Python bindings for the libwayland library"
+arch=(x86_64)
+url="https://github.com/flacjacket/pywayland"
+license=(Apache)
+depends=(python-cffi wayland)
+makedepends=(python-build python-installer python-setuptools wayland-protocols python-wheel)
+checkdepends=(python-pytest)
+options=(debug)
+source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
+sha512sums=('f27f4c375db26dcff5b42d377430810abf72fd98d8b24b4cd0671c97e5f8f0863fc71dcc9d7f2dcb60fdcd406218d6c70d5bc778e1cb9d08753d49972eec3e04')
+b2sums=('a2e0486a865a058fdc7cf3365a15c726b053e71179e9baec74695e5f195e65648cb93a30962be609970badad1f693a88c90ca763f7c9ca981526123f8136be39')
+
+build() {
+  cd $_name-$pkgver
+  python pywayland/ffi_build.py
+  python -m pywayland.scanner
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  local _py_ver="$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')"
+
+  cd $_name-$pkgver
+  mkdir -vp temp
+  export PYTHONPATH="build/lib.linux-$CARCH-$_py_ver:$PYTHONPATH"
+  export XDG_RUNTIME_DIR="$PWD/temp"
+  pytest -vv
+}
+
+package() {
+  cd $_name-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -vDm 644 README.rst -t "$pkgdir/usr/share/doc/$pkgname"
+}