[arch-commits] Commit in cbindgen/repos/extra-x86_64 (PKGBUILD PKGBUILD)

Jan Steffens heftig at gemini.archlinux.org
Tue Apr 19 14:03:47 UTC 2022


    Date: Tuesday, April 19, 2022 @ 14:03:47
  Author: heftig
Revision: 442923

archrelease: copy trunk to extra-x86_64

Added:
  cbindgen/repos/extra-x86_64/PKGBUILD
    (from rev 442921, cbindgen/trunk/PKGBUILD)
Deleted:
  cbindgen/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |   94 +++++++++++++++++++++++++++++++------------------------------
 1 file changed, 49 insertions(+), 45 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-04-19 14:03:47 UTC (rev 442922)
+++ PKGBUILD	2022-04-19 14:03:47 UTC (rev 442923)
@@ -1,45 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-
-pkgname=cbindgen
-pkgver=0.21.0
-pkgrel=1
-pkgdesc="A tool for generating C bindings to Rust code"
-url="https://github.com/eqrion/cbindgen"
-arch=(x86_64)
-license=(MPL2)
-depends=(gcc-libs)
-makedepends=(cargo git)
-checkdepends=(cython)
-_commit=b3de1dc4b438222ee8000afeeafdbe209adf337e  # tags/v0.21.0^0
-source=("git+https://github.com/eqrion/cbindgen#commit=$_commit")
-sha512sums=('SKIP')
-
-export CARGO_PROFILE_RELEASE_LTO=fat
-export CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1
-
-pkgver() {
-  cd cbindgen
-  git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
-}
-
-prepare() {
-  cd cbindgen
-  cargo fetch --locked --target x86_64-unknown-linux-gnu
-}
-
-build() {
-  cd cbindgen
-  cargo build --release --frozen --all-targets
-}
-
-check() {
-  cd cbindgen
-  # Tests need nightly features
-  RUSTC_BOOTSTRAP=1 cargo test --release --frozen
-}
-
-package() {
-  cd cbindgen
-  install -Dt "$pkgdir/usr/bin" target/release/cbindgen
-  install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 README.md
-}

Copied: cbindgen/repos/extra-x86_64/PKGBUILD (from rev 442921, cbindgen/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-04-19 14:03:47 UTC (rev 442923)
@@ -0,0 +1,49 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=cbindgen
+pkgver=0.22.0
+pkgrel=1
+pkgdesc="A tool for generating C bindings to Rust code"
+url="https://github.com/eqrion/cbindgen"
+arch=(x86_64)
+license=(MPL2)
+depends=(gcc-libs)
+makedepends=(cargo git)
+checkdepends=(cython)
+options=(debug)
+_commit=8604b2c0b720aab2582e169af4b0005d5d927770  # tags/v0.22.0^0
+source=("git+https://github.com/eqrion/cbindgen#commit=$_commit")
+sha512sums=('SKIP')
+
+# Use LTO
+export CARGO_PROFILE_RELEASE_LTO=true CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1
+
+# Use debug
+export CARGO_PROFILE_RELEASE_DEBUG=2
+
+pkgver() {
+  cd cbindgen
+  git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd cbindgen
+  cargo fetch --locked --target x86_64-unknown-linux-gnu
+}
+
+build() {
+  cd cbindgen
+  cargo build --release --frozen --all-targets
+}
+
+check() {
+  cd cbindgen
+  # Tests need nightly features
+  RUSTC_BOOTSTRAP=1 cargo test --release --frozen
+}
+
+package() {
+  cd cbindgen
+  install -Dt "$pkgdir/usr/bin" target/release/cbindgen
+  install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 README.md
+}



More information about the arch-commits mailing list