[arch-commits] Commit in (4 files)

[George Rawlinson]

    Date: Wednesday, April 20, 2022 @ 07:59:10
  Author: grawlinson
Revision: 1187116

addpkg: python-cli_helpers 2.2.1-2

Added:
  python-cli_helpers/
  python-cli_helpers/repos/
  python-cli_helpers/trunk/
  python-cli_helpers/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Added: python-cli_helpers/trunk/PKGBUILD
===================================================================
--- python-cli_helpers/trunk/PKGBUILD	                        (rev 0)
+++ python-cli_helpers/trunk/PKGBUILD	2022-04-20 07:59:10 UTC (rev 1187116)
@@ -0,0 +1,48 @@
+# Maintainer: George rawlinson <grawlinson at archlinux.org>
+# Contributor: fzerorubigd <fzero at rubi.gd>
+
+pkgname=python-cli_helpers
+pkgver=2.2.1
+pkgrel=2
+pkgdesc='Python helpers for common CLI tasks'
+arch=('any')
+url='https://github.com/dbcli/cli_helpers'
+license=('BSD')
+depends=(
+  'python'
+  'python-backports.csv'
+  'python-terminaltables'
+  'python-tabulate'
+)
+makedepends=('git' 'python-setuptools')
+checkdepends=('python-pytest' 'python-configobj')
+_commit='03ffe9e307b38b99c41a16dedd25f0266c96cdc0'
+source=("$pkgname::git+https://github.com/dbcli/cli_helpers.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cd "$pkgname"
+
+  python setup.py build
+}
+
+check() {
+  cd "$pkgname"
+
+  pytest \
+    --deselect tests/tabular_output/test_tabulate_adapter.py::test_tabulate_wrapper
+}
+
+package() {
+  cd "$pkgname"
+
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}