[arch-commits] Commit in nodejs/repos (3 files)

[Felix Yan]

    Date: Wednesday, April 20, 2022 @ 21:04:23
  Author: felixonmars
Revision: 1187199

archrelease: copy trunk to community-testing-x86_64

Added:
  nodejs/repos/community-testing-x86_64/
  nodejs/repos/community-testing-x86_64/PKGBUILD
    (from rev 1187198, nodejs/trunk/PKGBUILD)
  nodejs/repos/community-testing-x86_64/rebuild.list
    (from rev 1187198, nodejs/trunk/rebuild.list)

--------------+
 PKGBUILD     |   58 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 rebuild.list |    2 +
 2 files changed, 60 insertions(+)

Copied: nodejs/repos/community-testing-x86_64/PKGBUILD (from rev 1187198, nodejs/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-04-20 21:04:23 UTC (rev 1187199)
@@ -0,0 +1,58 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor  Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: James Campos <james.r.campos at gmail.com>
+# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
+# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
+# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
+# Contributor: TIanyi Cui <tianyicui at gmail.com>
+
+pkgname=nodejs
+pkgver=18.0.0
+pkgrel=1
+pkgdesc='Evented I/O for V8 javascript'
+arch=('x86_64')
+url='https://nodejs.org/'
+license=('MIT')
+options=(!lto)
+depends=('brotli' 'openssl' 'zlib' 'icu' 'libuv' 'libnghttp2' 'c-ares') # 'http-parser' 'v8')
+makedepends=('python' 'procps-ng')
+optdepends=('npm: nodejs package manager')
+source=("https://github.com/nodejs/node/archive/v$pkgver/nodejs-$pkgver.tar.gz")
+sha512sums=('a328a22c8046c10373c5574cbc3f5e931a9f1fdf1e97d3d21e6d305938b8840afb5365325058b9cea626e9a7e7d38fb4329eb04991b08092c7e2902f95ad3f62')
+
+build() {
+  cd node-$pkgver
+
+  ./configure \
+    --prefix=/usr \
+    --with-intl=system-icu \
+    --without-npm \
+    --shared-openssl \
+    --shared-zlib \
+    --shared-libuv \
+    --experimental-http-parser \
+    --shared-nghttp2 \
+    --shared-cares \
+    --shared-brotli
+    # --shared-v8
+    # --shared-http-parser
+
+  make
+}
+
+check() {
+  cd node-$pkgver
+  make test || :
+}
+
+package() {
+  cd node-$pkgver
+
+  make DESTDIR="$pkgdir" install
+
+  install -D -m644 LICENSE \
+    "$pkgdir"/usr/share/licenses/nodejs/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:

Copied: nodejs/repos/community-testing-x86_64/rebuild.list (from rev 1187198, nodejs/trunk/rebuild.list)
===================================================================
--- community-testing-x86_64/rebuild.list	                        (rev 0)
+++ community-testing-x86_64/rebuild.list	2022-04-20 21:04:23 UTC (rev 1187199)
@@ -0,0 +1,2 @@
+apm
+bash-language-server