[arch-commits] Commit in (memray memray/repos memray/trunk memray/trunk/PKGBUILD)

[Leonidas Spyropoulos]

    Date: Wednesday, April 20, 2022 @ 22:03:26
  Author: artafinde
Revision: 1187200

memray: Add 1.0.2 to repos

Added:
  memray/
  memray/repos/
  memray/trunk/
  memray/trunk/PKGBUILD

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Added: memray/trunk/PKGBUILD
===================================================================
--- memray/trunk/PKGBUILD	                        (rev 0)
+++ memray/trunk/PKGBUILD	2022-04-20 22:03:26 UTC (rev 1187200)
@@ -0,0 +1,39 @@
+# Maintainer: Leonidas Spyropoulos <artafinde at archlinux.org>
+
+pkgname=memray
+pkgver=1.0.2
+pkgrel=1
+pkgdesc="A memory profiler for Python"
+arch=('x86_64')
+url="https://github.com/bloomberg/memray"
+license=('Apache')
+depends=('python' 'libunwind')
+makedepends=('git' 'python-setuptools-scm' 'python-build' 'python-installer' 'python-wheel' 'cython' 'npm')
+checkdepends=('python-pytest')
+source=("git+$url.git?signed#tag=v$pkgver")
+sha512sums=('SKIP')
+validpgpkeys=('A035C8C19219BA821ECEA86B64E628F8D684696D') # Pablo Galindo Salgado <pablogsal at gmail.com>
+
+build() {
+  cd "${pkgname}"
+
+  export DIST_NAME='Arch Linux'
+  export DIST_PACKAGE="$pkgver-$pkgrel"
+  export SETUPTOOLS_SCM_PRETEND_VERSION="$pkgver"
+  export CFLAGS+=" -ffat-lto-objects"
+  export CXXFLAGS+=" -ffat-lto-objects"
+
+  make build dist
+}
+
+package() {
+  cd "${pkgname}"
+
+  python -m installer --destdir="${pkgdir}" dist/*.whl
+  # revisit below once https://github.com/bloomberg/memray/pull/20 is merged
+  ln -svf /usr/bin/memray3.10 "${pkgdir}"/usr/bin/memray
+
+  install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+# vim: ts=2 sw=2 et:
\ No newline at end of file