[arch-commits] Commit in k3b/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Thursday, April 21, 2022 @ 11:02:18
  Author: arojas
Revision: 443158

archrelease: copy trunk to testing-x86_64

Added:
  k3b/repos/testing-x86_64/
  k3b/repos/testing-x86_64/PKGBUILD
    (from rev 443157, k3b/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: k3b/repos/testing-x86_64/PKGBUILD (from rev 443157, k3b/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-04-21 11:02:18 UTC (rev 443158)
@@ -0,0 +1,39 @@
+# Maintainer: Eric Bélanger <eric at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgname=k3b
+pkgver=22.04.0
+pkgrel=1
+epoch=1
+pkgdesc='Feature-rich and easy to handle CD burning application'
+arch=(x86_64)
+url='https://apps.kde.org/k3b/'
+license=(GPL)
+depends=(libkcddb kcmutils knotifyconfig libmad kfilemetadata knewstuff
+         libmpcdec libdvdread libburn libsamplerate qt5-webkit)
+makedepends=(extra-cmake-modules kdoctools)
+optdepends=('cdrtools: for CD burning with cdrecord'
+            'dvd+rw-tools: for DVD burning support'
+            'vcdimager: for VCD burning support'
+            'emovix: for bootable multimedia CD/DVD support'
+            'cdrdao: for disk-at-once (DAO) mode support'
+            'cdparanoia: for CD ripping support' 'transcode: for DVD ripping support')
+groups=(kde-applications kde-multimedia)
+source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
+sha256sums=('5856d71fd5cf7f14eb646107f76e521869b4ac99df3411257c9f3427267b6504'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck at kde.org>
+              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker at kde.org>
+options=(debug)
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}