[arch-commits] Commit in konversation/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Thursday, April 21, 2022 @ 11:04:44
  Author: arojas
Revision: 443170

archrelease: copy trunk to testing-x86_64

Added:
  konversation/repos/testing-x86_64/
  konversation/repos/testing-x86_64/PKGBUILD
    (from rev 443169, konversation/trunk/PKGBUILD)

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Copied: konversation/repos/testing-x86_64/PKGBUILD (from rev 443169, konversation/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-04-21 11:04:44 UTC (rev 443170)
@@ -0,0 +1,35 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Tom Gundersen <teg at jklm.no>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: James Rayner <iphitus at gmail.com>
+# Contributor: Sergio Jovani Guzman <moret at paretux.org>
+
+pkgname=konversation
+pkgver=22.04.0
+pkgrel=1
+pkgdesc='A user-friendly and fully-featured IRC client'
+arch=(x86_64)
+url='https://apps.kde.org/konversation/'
+depends=(knotifyconfig kparts kidletime knewstuff qca-qt5 hicolor-icon-theme perl)
+optdepends=('python: python scripting support' 'keditbookmarks: for managing bookmarks')
+makedepends=(extra-cmake-modules kdoctools)
+license=(GPL2 FDL)
+groups=(kde-applications kde-network)
+source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
+sha256sums=('f89c3854edd6dabcceff7a3615b532ac34d5b4769be1e125789e41d67e7f9b8a'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck at kde.org>
+              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker at kde.org>
+options=(debug)
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}