[arch-commits] Commit in (7 files)

Antonio Rojas arojas at gemini.archlinux.org
Fri Apr 22 08:38:12 UTC 2022


    Date: Friday, April 22, 2022 @ 08:38:11
  Author: arojas
Revision: 1187296

extra2community: Moving r from extra to community

Added:
  r/
  r/repos/
  r/trunk/
  r/trunk/PKGBUILD
  r/trunk/R.conf
  r/trunk/r.desktop
  r/trunk/r.png

-----------+
 PKGBUILD  |   86 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 R.conf    |    2 +
 r.desktop |   11 +++++++
 r.png     |    1 
 4 files changed, 100 insertions(+)

Added: r/trunk/PKGBUILD
===================================================================
--- r/trunk/PKGBUILD	                        (rev 0)
+++ r/trunk/PKGBUILD	2022-04-22 08:38:11 UTC (rev 1187296)
@@ -0,0 +1,86 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Ronald van Haren <ronald.archlinux.org>
+# Contributor: Damir Perisa <damir.perisa at bluewin.ch>
+# Contributor: K. Piche <kpiche at rogers.com>
+
+pkgname=r
+pkgver=4.1.3
+pkgrel=2
+pkgdesc='Language and environment for statistical computing and graphics'
+arch=(x86_64)
+license=(GPL)
+url='https://www.r-project.org/'
+depends=(lapack libtiff pcre2 perl libxmu pango zip unzip curl icu which)
+makedepends=(jdk-openjdk gcc-fortran tk texlive-core)
+optdepends=('tk: tcl/tk interface'
+            'texlive-bin: latex sty files'
+            'gcc-fortran: needed to compile some CRAN packages'
+            'openblas: faster linear algebra')
+backup=('etc/R/Makeconf' 'etc/R/Renviron' 'etc/R/ldpaths' 'etc/R/repositories' 'etc/R/javaconf')
+options=(!emptydirs)
+source=(https://cran.r-project.org/src/base/R-${pkgver%%.*}/R-$pkgver.tar.gz
+	r.desktop
+	r.png
+	R.conf)
+sha256sums=('15ff5b333c61094060b2a52e9c1d8ec55cc42dd029e39ca22abdaa909526fed6'
+            '25b01ea93fa704884b65ba002d44d4e99725bd826997e8c73b6467df9f23c798'
+            '1580d06a737951f4f3c903cbd514247d9071fc6868eb9c2de94bb999cc195cb1'
+            'b7833166041b06f716b6a79095d27d4abd83549816dc53193213827139eae6ef')
+
+prepare() {
+  cd R-$pkgver
+  # set texmf dir correctly in makefile
+  sed -i 's|$(rsharedir)/texmf|${datarootdir}/texmf|' share/Makefile.in
+}
+
+build() {
+  cd R-$pkgver
+  ./configure  --prefix=/usr \
+               --libdir=/usr/lib \
+               --sysconfdir=/etc/R \
+               --datarootdir=/usr/share \
+               rsharedir=/usr/share/R/ \
+               rincludedir=/usr/include/R/ \
+               rdocdir=/usr/share/doc/R/ \
+               --with-x \
+               --enable-R-shlib \
+               --with-lapack \
+               --with-blas \
+               F77=gfortran \
+               LIBnn=lib
+  make
+  make pdf info
+
+  cd src/nmath/standalone
+  make shared
+}
+
+package() {
+  cd R-$pkgver
+  make DESTDIR="$pkgdir" install install-pdf install-info
+
+# install libRmath.so
+  cd src/nmath/standalone
+  make DESTDIR="$pkgdir" install
+
+# Fixup R wrapper scripts.
+  sed -i "s|$pkgdir ||" "${pkgdir}/usr/bin/R"
+  rm "$pkgdir"/usr/lib/R/bin/R
+  cd "$pkgdir"/usr/lib/R/bin
+  ln -s ../../../bin/R
+
+# install some freedesktop.org compatibility
+  install -Dm644 "$srcdir"/r.desktop -t "$pkgdir"/usr/share/applications
+  install -Dm644 "$srcdir"/r.png -t "$pkgdir"/usr/share/pixmaps
+
+# move the config directory to /etc and create symlinks
+  install -d "$pkgdir"/etc/R
+  cd "$pkgdir"/usr/lib/R/etc
+  for _i in *; do
+    mv -f $_i "$pkgdir"/etc/R
+    ln -s /etc/R/$_i $_i
+  done
+
+# Install ld.so.conf.d file to ensure other applications access the shared lib
+  install -Dm644 "$srcdir"/R.conf -t "$pkgdir"/etc/ld.so.conf.d
+}

Added: r/trunk/R.conf
===================================================================
--- r/trunk/R.conf	                        (rev 0)
+++ r/trunk/R.conf	2022-04-22 08:38:11 UTC (rev 1187296)
@@ -0,0 +1,2 @@
+/usr/lib/R/lib
+

Added: r/trunk/r.desktop
===================================================================
--- r/trunk/r.desktop	                        (rev 0)
+++ r/trunk/r.desktop	2022-04-22 08:38:11 UTC (rev 1187296)
@@ -0,0 +1,11 @@
+[Desktop Entry]
+Name=R
+GenericName=environment for statistical computing
+Comment=language and environment for statistical computing and graphics
+Exec=R
+Icon=/usr/share/pixmaps/r.png
+DocPath=/usr/lib/R/doc/html/index.html
+StartupNotify=true
+Terminal=true
+Type=Application
+Categories=Math;Science;Education

Added: r/trunk/r.png
===================================================================
(Binary files differ)

Index: r/trunk/r.png
===================================================================
--- r/trunk/r.png	2022-04-22 08:28:26 UTC (rev 1187295)
+++ r/trunk/r.png	2022-04-22 08:38:11 UTC (rev 1187296)

Property changes on: r/trunk/r.png
___________________________________________________________________
Added: svn:mime-type
## -0,0 +1 ##
+image/png
\ No newline at end of property


More information about the arch-commits mailing list