[arch-commits] Commit in nikola/trunk (PKGBUILD)

[David Runge]

    Date: Saturday, April 23, 2022 @ 16:13:47
  Author: dvzrv
Revision: 1187649

upgpkg: nikola 8.2.1-1: Upgrade to 8.2.1.

Remove unneeded quotes and curly braces.
Switch to PEP517.

Modified:
  nikola/trunk/PKGBUILD

----------+
 PKGBUILD |   91 +++++++++++++++++++++++++++----------------------------------
 1 file changed, 41 insertions(+), 50 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-04-23 15:58:06 UTC (rev 1187648)
+++ PKGBUILD	2022-04-23 16:13:47 UTC (rev 1187649)
@@ -2,7 +2,7 @@
 
 _name=Nikola
 pkgname=nikola
-pkgver=8.2.0
+pkgver=8.2.1
 pkgrel=1
 pkgdesc="A static site and blog generator"
 arch=(any)
@@ -13,70 +13,61 @@
 python-docutils python-logbook python-lxml python-mako python-markdown
 python-natsort python-piexif python-pillow python-pygments python-pyrss2gen
 python-requests python-setuptools python-unidecode python-yapsy)
-makedepends=(jupyter-notebook python-aiohttp python-ghp-import python-husl
-python-ipykernel python-jinja python-micawber python-phpserialize python-pygal
-python-pyphen python-ruamel-yaml python-toml python-typogrify python-watchdog
-zeromq)
+makedepends=(jupyter-notebook python-aiohttp python-build python-ghp-import
+python-husl python-installer python-ipykernel python-jinja python-micawber
+python-phpserialize python-pygal python-pyphen python-ruamel-yaml python-toml
+python-typogrify python-watchdog python-wheel zeromq)
 checkdepends=(python-freezegun python-pytest)
-optdepends=('jupyter-notebook: for .ipynb support'
-            'python-aiohttp: for `nikola auto`'
-            'python-ghp-import: for upload to Github pages'
-            'python-hsluv: for section color mixing'
-            'python-html5lib: for HTML5 minify and format support'
-            'python-husl: for optional color support'
-            'python-ipykernel: for .ipynb support'
-            'python-jinja: for jinja2 based themes'
-            'python-micawber: for embedding media in posts'
-            'python-phpserialize: for Wordpress import'
-            'python-pygal: for SVG graph plotting'
-            'python-pyphen: for hyphenation support'
-            'python-ruamel-yaml: for YAML support'
-            'python-toml: for TOML support'
-            'python-typogrify: for typographical enhancements'
-            'python-watchdog: for `nikola auto`')
-source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz"{,.asc})
-sha512sums=('c55450791da2e71bb57f44816aae866d6fc5d20c632fb93f9224ab9c7e630b9a1ba8cd2fb569b0f0c416d3246aaeada8bd5571fed8ee3bdce9eb3865c89402bf'
+optdepends=(
+  'jupyter-notebook: for .ipynb support'
+  'python-aiohttp: for `nikola auto`'
+  'python-ghp-import: for upload to Github pages'
+  'python-hsluv: for section color mixing'
+  'python-html5lib: for HTML5 minify and format support'
+  'python-husl: for optional color support'
+  'python-ipykernel: for .ipynb support'
+  'python-jinja: for jinja2 based themes'
+  'python-micawber: for embedding media in posts'
+  'python-phpserialize: for Wordpress import'
+  'python-pygal: for SVG graph plotting'
+  'python-pyphen: for hyphenation support'
+  'python-ruamel-yaml: for YAML support'
+  'python-toml: for TOML support'
+  'python-typogrify: for typographical enhancements'
+  'python-watchdog: for `nikola auto`'
+)
+source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz{,.asc})
+sha512sums=('5893cc7a3eb876fc1c165e91bcc03db9674c9b6569b89fb10ce111bc9f3a7f8b72d54641429a8d882a3a2ac9aa59e5ed665b23f8d37c9679cc9aff5b8d839ccb'
             'SKIP')
-b2sums=('04ff867295caed134558dc81e9c7cf3a7e607792cc0bc6aec670a45e443c15a1f89b1a8062fbc0a1af3e41951e843eac5106daf53b6121dd95aae0984967df75'
+b2sums=('4e9514984d5e813421f374d67018d266aa56c63674b8c1070ad2bc0685d6d59a08be38b1422808564653d6c4f80e2ad40ca7facb7d0ea0185bcd13f136c4b915'
         'SKIP')
 validpgpkeys=('DF32C99CFF84282CF9D4CF7171023DBD5EAAEA16') # Chris Warrick <kwpolska at gmail.com>
 
 prepare() {
-  mv -v "${_name}-$pkgver" "$pkgname-$pkgver"
-  cd "$pkgname-$pkgver"
-  # remove options to pytest so that we don't require python-coverage et. al.
-  sed -e '/addopts/d' -i setup.cfg
+  sed -e '/addopts/d' -i $_name-$pkgver/setup.cfg
 }
 
 build() {
-  cd "$pkgname-$pkgver"
-  python setup.py build
+  cd $_name-$pkgver
+  python -m build --wheel --no-isolation
+
   # shell completions
-  PYTHONPATH="build" \
-  python -m "${pkgname}" tabcompletion \
-    --shell bash \
-    --hardcode-tasks \
-    > "${pkgname}_bash"
-  PYTHONPATH="build" \
-  python -m "${pkgname}" tabcompletion \
-    --shell zsh \
-    --hardcode-tasks \
-    > "${pkgname}_zsh"
+  python -m $pkgname tabcompletion --shell bash --hardcode-tasks > ${pkgname}_bash
+  python -m $pkgname tabcompletion --shell zsh --hardcode-tasks > ${pkgname}_zsh
   # ensure that the shell completion is assigned to the correct executable
-  sed -e "s/__main__.py/${pkgname}/g" -i "${pkgname}_"{bash,zsh}
+  sed -e "s/__main__.py/$pkgname/g" -i "${pkgname}_"{bash,zsh}
 }
 
 check() {
-  cd "$pkgname-$pkgver"
-  export PYTHONPATH="build:${PYTHONPATH}"
-  pytest -v -k "not test_compiling_markdown"
+  cd $_name-$pkgver
+  pytest -vv -k "not test_compiling_markdown"
 }
 
 package() {
-  cd "$pkgname-$pkgver"
-  python setup.py install --optimize=1 --root="${pkgdir}"
-  install -vDm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
-  install -vDm 644 {AUTHORS,CHANGES}.txt {CONTRIBUTING,README}.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
-  install -vDm 644 "${pkgname}_bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
-  install -vDm 644 "${pkgname}_zsh" "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
+  cd $_name-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -vDm 644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
+  install -vDm 644 {AUTHORS,CHANGES}.txt {CONTRIBUTING,README}.rst -t "$pkgdir/usr/share/doc/$pkgname/"
+  install -vDm 644 ${pkgname}_bash "$pkgdir/usr/share/bash-completion/completions/$pkgname"
+  install -vDm 644 ${pkgname}_zsh "$pkgdir/usr/share/zsh/site-functions/_$pkgname"
 }