[arch-commits] Commit in haskell-vector/repos (2 files)

[Felix Yan]

    Date: Saturday, April 23, 2022 @ 17:57:48
  Author: felixonmars
Revision: 1187740

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-vector/repos/community-staging-x86_64/
  haskell-vector/repos/community-staging-x86_64/PKGBUILD
    (from rev 1187739, haskell-vector/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-vector/repos/community-staging-x86_64/PKGBUILD (from rev 1187739, haskell-vector/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-04-23 17:57:48 UTC (rev 1187740)
@@ -0,0 +1,52 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+
+pkgname=haskell-vector
+pkgver=0.12.3.1
+pkgrel=76
+pkgdesc="Efficient Arrays"
+url="https://hackage.haskell.org/package/vector"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-primitive')
+makedepends=('ghc' 'uusi' 'haskell-base-orphans' 'haskell-doctest' 'haskell-hunit' 'haskell-quickcheck'
+             'haskell-random' 'haskell-tasty' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/vector/${pkgver}/vector-${pkgver}.tar.gz")
+sha512sums=('bf117d53c7844c010dc1cee8b778851bd714155fd34e671ae2eb7bd324427de972389eb9f3f315832f20e7bbbecc93ec0f6296ab10e4935957d2a4e14c6cfd98')
+
+prepare() {
+  cd vector-${pkgver}
+  uusi -u doctest vector.cabal
+}
+
+build() {
+  cd "$srcdir"/vector-${pkgver}
+
+  if (( CHECKFUNC )); then
+      _opts=('--enable-tests')
+  else
+      _opts=('--disable-tests')
+  fi
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+      --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname "${_opts[@]}" \
+      --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd vector-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd "$srcdir"/vector-${pkgver}
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/${pkgname}/LICENSE
+  rm -f "$pkgdir"/usr/share/doc/${pkgname}/LICENSE
+}