[arch-commits] Commit in apache-orc/repos (2 files)
Evangelos Foutras
foutrelis at gemini.archlinux.org
Sat Apr 23 18:31:45 UTC 2022
Date: Saturday, April 23, 2022 @ 18:31:44
Author: foutrelis
Revision: 1187846
archrelease: copy trunk to community-staging-x86_64
Added:
apache-orc/repos/community-staging-x86_64/
apache-orc/repos/community-staging-x86_64/PKGBUILD
(from rev 1187845, apache-orc/trunk/PKGBUILD)
----------+
PKGBUILD | 51 +++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 51 insertions(+)
Copied: apache-orc/repos/community-staging-x86_64/PKGBUILD (from rev 1187845, apache-orc/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-04-23 18:31:44 UTC (rev 1187846)
@@ -0,0 +1,51 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Guillaume Horel <guillaume.horel at gmail.com>
+
+_pkg=orc
+pkgname=apache-${_pkg}
+pkgver=1.7.3
+pkgrel=2
+pkgdesc="Columnar storage for Hadoop workloads."
+arch=(x86_64)
+url="https://orc.apache.org"
+license=(Apache)
+depends=(lz4 protobuf snappy zlib zstd)
+makedepends=(cmake)
+checkdepends=(gtest)
+options=(staticlibs)
+source=(https://archive.apache.org/dist/${_pkg}/${_pkg}-${pkgver}/${_pkg}-${pkgver}.tar.gz{,.asc}
+ ${pkgname}-fix-ByteSize-Long.patch::https://github.com/apache/orc/commit/ffbd34115322cf3e0eb6963002c540ea449362d2.patch)
+sha256sums=(535c4d7588172e85b8fc941cd0575d67f2155a55e4cd65d87d5b194b0bb28a31 SKIP
+ cab14490e0cf8f229bb22b3d4269899a9c2522bcedba5878008b1900001d3b20)
+validpgpkeys=(F28C9C925C188C35E345614DEDA00CE834F0FC5C) # Dongjoon Hyun (CODE SIGNING KEY) <dongjoon at apache.org>
+
+prepare(){
+ cd ${_pkg}-${pkgver}
+ patch -p1 < ../${pkgname}-fix-ByteSize-Long.patch
+}
+
+build(){
+ cmake -B build -S ${_pkg}-${pkgver} \
+ -DCMAKE_CXX_FLAGS="${CXXFLAGS} -fPIC -ffat-lto-objects" \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX="/usr" \
+ -DLZ4_HOME="/usr" \
+ -DPROTOBUF_HOME="/usr" \
+ -DSNAPPY_HOME="/usr" \
+ -DZLIB_HOME="/usr" \
+ -DZSTD_HOME="/usr" \
+ -DORC_PREFER_STATIC_ZLIB=OFF \
+ -DBUILD_LIBHDFSPP=OFF \
+ -DBUILD_JAVA=OFF \
+ -DINSTALL_VENDORED_LIBS=OFF
+ make -C build
+}
+
+check(){
+ # Some tests failures https://github.com/apache/orc/issues/1068
+ make -C build test-out || echo "Warning: Tests failed"
+}
+
+package(){
+ make DESTDIR="${pkgdir}" -C build install
+}
More information about the arch-commits
mailing list