[arch-commits] Commit in haskell-unordered-containers/repos (2 files)

[Felix Yan]

    Date: Saturday, April 23, 2022 @ 21:45:24
  Author: felixonmars
Revision: 1188726

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-unordered-containers/repos/community-staging-x86_64/
  haskell-unordered-containers/repos/community-staging-x86_64/PKGBUILD
    (from rev 1188725, haskell-unordered-containers/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-unordered-containers/repos/community-staging-x86_64/PKGBUILD (from rev 1188725, haskell-unordered-containers/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-04-23 21:45:24 UTC (rev 1188726)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Nagy <danielnagy at gmx de>
+# Contributor: Daniel Micay <danielmicay at gmail.com>
+# Contributor: Martin Harvan <martinhrvn at gmail.com>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=unordered-containers
+pkgname=haskell-unordered-containers
+pkgver=0.2.18.0
+pkgrel=3
+pkgdesc="Efficient hashing-based container types"
+url="https://github.com/haskell-unordered-containers/unordered-containers"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-hashable')
+makedepends=('ghc' 'haskell-chasingbottoms' 'haskell-hunit' 'haskell-nothunks' 'haskell-quickcheck'
+             'haskell-random' 'haskell-tasty' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('3551a8be27eefaf3990b25ad939a967f8b1b84b95c4948484bfee432b5cd6d9abae7b1b1db429472eb4df1c7c3eba7dc6bfa4e659697877846cc860c512520ea')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-debug
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}