[arch-commits] Commit in haskell-warp/repos (2 files)

[Felix Yan]

    Date: Saturday, April 23, 2022 @ 23:05:43
  Author: felixonmars
Revision: 1189223

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-warp/repos/community-staging-x86_64/
  haskell-warp/repos/community-staging-x86_64/PKGBUILD
    (from rev 1189222, haskell-warp/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-warp/repos/community-staging-x86_64/PKGBUILD (from rev 1189222, haskell-warp/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-04-23 23:05:43 UTC (rev 1189223)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=warp
+pkgname=haskell-warp
+pkgver=3.3.20
+pkgrel=23
+pkgdesc="A fast, light-weight web server for WAI applications."
+url="https://github.com/yesodweb/wai"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-auto-update' 'haskell-bsb-http-chunked'
+         'haskell-case-insensitive' 'haskell-hashable' 'haskell-http-date' 'haskell-http-types'
+         'haskell-http2' 'haskell-iproute' 'haskell-network' 'haskell-simple-sendfile'
+         'haskell-streaming-commons' 'haskell-time-manager' 'haskell-unix-compat'
+         'haskell-unliftio' 'haskell-vault' 'haskell-wai' 'haskell-word8' 'haskell-x509')
+makedepends=('ghc' 'haskell-async' 'haskell-doctest' 'haskell-http-client' 'haskell-hspec'
+             'haskell-hunit' 'haskell-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('5ba8818b637e00deefc219d29b01a108669f0ca86df9404b92834e8409f6df573ee12ff7358aff6e401ad6530093f9d86a8eb3991cbc560f2491d2552c3dee27')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-warp-debug -fallow-sendfilefd -f-network-bytestring
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}