[arch-commits] Commit in sdl2/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Sven-Hendrik Haase]

    Date: Monday, April 25, 2022 @ 21:12:40
  Author: svenstaro
Revision: 443973

archrelease: copy trunk to testing-x86_64

Added:
  sdl2/repos/testing-x86_64/
  sdl2/repos/testing-x86_64/PKGBUILD
    (from rev 443972, sdl2/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: sdl2/repos/testing-x86_64/PKGBUILD (from rev 443972, sdl2/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-04-25 21:12:40 UTC (rev 443973)
@@ -0,0 +1,42 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at archlinux.org>
+pkgname=sdl2
+pkgver=2.0.22
+pkgrel=1
+pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 2)"
+arch=('x86_64')
+url="https://www.libsdl.org"
+license=('MIT')
+depends=('glibc' 'libxext' 'libxrender' 'libx11' 'libgl' 'libxcursor' 'libibus' 'hidapi' 'libusb')
+makedepends=('alsa-lib' 'mesa' 'libpulse' 'libxrandr' 'libxinerama' 'wayland' 'libxkbcommon'
+             'wayland-protocols' 'ibus' 'fcitx5' 'libxss' 'cmake' 'jack' 'ninja' 'pipewire'
+             'libdecor')
+optdepends=('alsa-lib: ALSA audio driver'
+            'libpulse: PulseAudio audio driver'
+            'jack: JACK audio driver'
+            'pipewire: PipeWire audio driver'
+            'libdecor: Wayland client decorations')
+source=("https://www.libsdl.org/release/SDL2-${pkgver}.tar.gz"{,.sig})
+sha512sums=('ca4b690433cd4d9d73b797da98666317128e7e817ab60e874a49d94791ea41e8a6b4fc43649593120daa0702190c0f8a6ed326c908d87375c8da9f369d994f6a'
+            'SKIP')
+validpgpkeys=('1528635D8053A57F77D1E08630A59377A7763BE6') # Sam Lantinga
+
+build() {
+  CFLAGS+=" -ffat-lto-objects"
+  cmake -S SDL2-${pkgver} -B build -G Ninja \
+    -D CMAKE_INSTALL_PREFIX=/usr \
+    -D SDL_STATIC=OFF \
+    -D SDL_DLOPEN=ON \
+    -D SDL_RPATH=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --install build
+
+  # For some reason, this isn't named correctly and we have to fix it to reflect the actual staticlib name.
+  sed -i "s/libSDL2\.a/libSDL2main.a/g" "$pkgdir"/usr/lib/cmake/SDL2/SDL2Targets-noconfig.cmake
+
+  install -Dm644 SDL2-${pkgver}/LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et: