[arch-commits] Commit in runc/repos (2 files)

[Frederik Schwan]

    Date: Wednesday, April 27, 2022 @ 14:43:17
  Author: freswa
Revision: 1191162

archrelease: copy trunk to community-staging-x86_64

Added:
  runc/repos/community-staging-x86_64/
  runc/repos/community-staging-x86_64/PKGBUILD
    (from rev 1191161, runc/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: runc/repos/community-staging-x86_64/PKGBUILD (from rev 1191161, runc/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-04-27 14:43:17 UTC (rev 1191162)
@@ -0,0 +1,50 @@
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Maintainer: Frederik Schwan <freswa at archlinux dot org>
+# Contributor: Sébastien "Seblu" Luttringer
+
+pkgname=runc
+pkgver=1.1.1
+pkgrel=2
+pkgdesc='CLI tool for managing OCI compliant containers'
+arch=(x86_64)
+url='https://runc.io/'
+license=(Apache)
+depends=(libseccomp)
+makedepends=(git go go-md2man)
+optdepends=(
+  'criu: checkpoint support'
+)
+source=("${pkgname}-${pkgver}.tar.xz::https://github.com/opencontainers/runc/releases/download/v${pkgver}/runc.tar.xz"
+        "${pkgname}-${pkgver}.tar.xz.sig::https://github.com/opencontainers/runc/releases/download/v${pkgver}/runc.tar.xz.asc")
+validpgpkeys=("5F36C6C61B5460124A75F5A69E18AA267DDB8DB4"
+			  "C9C370B246B09F6DBCFC744C34401015D1D2D386")
+sha256sums=('75c1f0bb19b209412c52599e24b33ac306cf7caf772c97577b7ebe964837a54b'
+            'SKIP')
+
+prepare() {
+  mkdir -p src/github.com/opencontainers
+  cp -r runc-${pkgver} src/github.com/opencontainers/runc
+}
+
+build() {
+  cd src/github.com/opencontainers/runc
+  export GOPATH="$srcdir"
+  export BUILDTAGS='seccomp apparmor'
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export GOFLAGS="-trimpath -mod=readonly -modcacherw"
+  make runc man
+}
+
+package() {
+  cd src/github.com/opencontainers/runc
+
+  install -Dm755 runc "$pkgdir/usr/bin/runc"
+  install -Dm644 contrib/completions/bash/runc \
+    "$pkgdir/usr/share/bash-completion/completions/runc"
+  
+  install -d "$pkgdir/usr/share/man/man8"
+  install -m644 man/man8/*.8 "$pkgdir/usr/share/man/man8"
+}