[arch-commits] Commit in archinstall/trunk (PKGBUILD)

[David Runge]

    Date: Thursday, April 28, 2022 @ 12:37:43
  Author: dvzrv
Revision: 444211

upgpkg: archinstall 2.4.1-1: Upgrade to 2.4.1.

Remove unneeded quotes and curly braces.
Switch to PEP517 (by replacing symlinks with real directories).

Modified:
  archinstall/trunk/PKGBUILD

----------+
 PKGBUILD |   43 ++++++++++++++++++++++++++-----------------
 1 file changed, 26 insertions(+), 17 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-04-28 12:35:50 UTC (rev 444210)
+++ PKGBUILD	2022-04-28 12:37:43 UTC (rev 444211)
@@ -1,37 +1,46 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
 # Maintainer: Giancarlo Razzolini <grazzolini at archlinux.org>
 # Contributor: Anton Hvornum <anton at hvornum.se>
 # Contributor: demostanis worlds <demostanis at protonmail.com>
 
 pkgname=archinstall
-pkgver=2.3.3
+pkgver=2.4.1
 pkgrel=1
 pkgdesc="Just another guided/automated Arch Linux installer with a twist"
-arch=('any')
+arch=(any)
 url="https://github.com/archlinux/archinstall"
-license=('GPL3')
-depends=('python')
-makedepends=('python-setuptools' 'python-sphinx')
-provides=('python-archinstall')
-conflicts=('python-archinstall')
-replaces=('python-archinstall')
-source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz"
-        "$pkgname-$pkgver.tar.gz.sig::$url/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz.sig")
-sha512sums=('21df4342af6a5c6d4eebc12f31f81210689749aaa49016a344b8c6a2ebd58ed1ada6f02f48f70eef893be5fe0c33670975545d4928f681518b9484ec7ba787ec'
+license=(GPL3)
+depends=(python)
+makedepends=(python-build python-installer python-flit python-setuptools python-sphinx python-wheel)
+provides=(python-archinstall)
+conflicts=(python-archinstall)
+replaces=(python-archinstall)
+source=(
+  $pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz
+  $pkgname-$pkgver.tar.gz.sig::$url/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz.sig
+)
+sha512sums=('9516719c4e4fe0423224a35b4846cf5c8daeb931cff6fed588957840edc5774e9c6fe18619d2356a6d76681ae3216ba19f5d0f0bd89c6301b4ff9b128d037d13'
             'SKIP')
-b2sums=('cca4ecaacf3081c21078d17790843dba28e26323c1036ef91be6ed7dff6a891cc62b76a01700f5ab23fcffe1a29302b8f78b24986fe0927b9222d99312c20c8d'
+b2sums=('a29ae767756f74ce296d53e31bb8376cfa7db19a53b8c3997b2d8747a60842ba88e8b18c505bc56a36d685f73f7a6d9e53adff17953c8a4ebaabc67c6db8e583'
         'SKIP')
 validpgpkeys=('256F73CEEFC6705C6BBAB20E5FBBB32941E3740A') # Anton Hvornum (Torxed) <anton at hvornum.se>
 
+prepare() {
+  cd $pkgname-$pkgver
+  # use real directories for examples and profiles, as symlinks do not work
+  # with flit or setuptools PEP517 backends
+  rm -fv $pkgname/{examples,profiles}
+  mv -v examples profiles $pkgname/
+}
 
 build() {
-  cd "$pkgname-$pkgver"
-  python setup.py build
+  cd $pkgname-$pkgver
+  python -m build --wheel --no-isolation
   PYTHONDONTWRITEBYTECODE=1 make man -C docs
 }
 
 package() {
   cd "$pkgname-$pkgver"
-
-  python setup.py install --root="${pkgdir}" --optimize=1
-  install -vDm 644 docs/_build/man/archinstall.1 -t "${pkgdir}/usr/share/man/man1/"
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -vDm 644 docs/_build/man/archinstall.1 -t "$pkgdir/usr/share/man/man1/"
 }