[arch-commits] Commit in libqmi/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Thursday, April 28, 2022 @ 20:09:02
  Author: heftig
Revision: 444244

archrelease: copy trunk to extra-x86_64

Added:
  libqmi/repos/extra-x86_64/PKGBUILD
    (from rev 444243, libqmi/trunk/PKGBUILD)
Deleted:
  libqmi/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |   81 ++++++++++++++++++++++++++++---------------------------------
 1 file changed, 38 insertions(+), 43 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-04-28 20:08:52 UTC (rev 444243)
+++ PKGBUILD	2022-04-28 20:09:02 UTC (rev 444244)
@@ -1,43 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-
-pkgname=libqmi
-pkgver=1.30.4
-pkgrel=1
-pkgdesc="QMI modem protocol helper library"
-arch=(x86_64)
-url="https://www.freedesktop.org/wiki/Software/libqmi/"
-license=(GPL2)
-depends=(libmbim libqrtr-glib libgudev)
-makedepends=(gtk-doc python git help2man gobject-introspection)
-provides=(libqmi-glib.so)
-_commit=f6c2feaf199e0f129a0bde8c5e6cba5f2117b564  # tags/1.30.4
-source=("git+https://gitlab.freedesktop.org/mobile-broadband/libqmi.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd libqmi
-  git describe --tags | sed 's/-rc/rc/;s/[^-]*-g/r&/;s/-/+/g'
-}
-
-prepare() {
-  cd libqmi
-  NOCONFIGURE=1 ./autogen.sh
-}
-
-build() {
-  cd libqmi
-  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
-    --libexecdir=/usr/lib --disable-static --enable-gtk-doc \
-    --enable-compile-warnings=yes
-  make
-}
-
-check() {
-  cd libqmi
-  make check
-}
-
-package() {
-  cd libqmi
-  make DESTDIR="$pkgdir" install
-}

Copied: libqmi/repos/extra-x86_64/PKGBUILD (from rev 444243, libqmi/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-04-28 20:09:02 UTC (rev 444244)
@@ -0,0 +1,38 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=libqmi
+pkgver=1.30.6
+pkgrel=1
+pkgdesc="QMI modem protocol helper library"
+url="https://www.freedesktop.org/wiki/Software/libqmi/"
+arch=(x86_64)
+license=(GPL2)
+depends=(libmbim libqrtr-glib libgudev)
+makedepends=(gtk-doc meson git help2man gobject-introspection bash-completion)
+provides=(libqmi-glib.so)
+options=(debug)
+_commit=dc82a0ae42df0086fab0595690dd3bbd7a958773  # tags/1.30.6^0
+source=("git+https://gitlab.freedesktop.org/mobile-broadband/libqmi.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd libqmi
+  git describe --tags | sed 's/-rc/rc/;s/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd libqmi
+}
+
+build() {
+  arch-meson libqmi build -D gtk_doc=false  # Docs currently broken
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}