[arch-commits] Commit in nvidia/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Frederik Schwan]

    Date: Monday, August 1, 2022 @ 22:16:47
  Author: freswa
Revision: 451849

archrelease: copy trunk to staging-x86_64

Added:
  nvidia/repos/staging-x86_64/
  nvidia/repos/staging-x86_64/PKGBUILD
    (from rev 451848, nvidia/trunk/PKGBUILD)

----------+
 PKGBUILD |   33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)

Copied: nvidia/repos/staging-x86_64/PKGBUILD (from rev 451848, nvidia/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-08-01 22:16:47 UTC (rev 451849)
@@ -0,0 +1,33 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Baechler <thomas at archlinux.org>
+
+pkgname=nvidia
+pkgver=515.57
+pkgrel=11
+pkgdesc="NVIDIA drivers for linux"
+arch=('x86_64')
+url="https://www.nvidia.com/"
+makedepends=('linux-headers' "nvidia-dkms=$pkgver")
+provides=('NVIDIA-MODULE')
+license=('custom')
+options=('!strip')
+
+build() {
+    _kernver=$(</usr/src/linux/version)
+
+    fakeroot dkms build --dkmstree "${srcdir}" -m nvidia/${pkgver} -k ${_kernver}
+}
+
+package() {
+    depends=('linux' "nvidia-utils=${pkgver}" 'libglvnd')
+
+    _kernver="$(</usr/src/linux/version)"
+
+    install -Dt "${pkgdir}/usr/lib/modules/${_kernver}/extramodules" -m644 nvidia/${pkgver}/${_kernver}/${CARCH}/module/*
+
+    # compress each module individually
+    find "$pkgdir" -name '*.ko' -exec xz -T1 {} +
+
+    install -Dm644 /usr/share/licenses/nvidia-dkms/LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}