[arch-commits] Commit in tmuxp/repos (2 files)

[David Runge]

    Date: Monday, August 1, 2022 @ 23:34:51
  Author: dvzrv
Revision: 1259738

archrelease: copy trunk to community-staging-any

Added:
  tmuxp/repos/community-staging-any/
  tmuxp/repos/community-staging-any/PKGBUILD
    (from rev 1259737, tmuxp/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: tmuxp/repos/community-staging-any/PKGBUILD (from rev 1259737, tmuxp/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2022-08-01 23:34:51 UTC (rev 1259738)
@@ -0,0 +1,40 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+pkgname=tmuxp
+pkgver=1.12.0
+pkgrel=1
+pkgdesc="Tmux session manager built on libtmux"
+arch=(any)
+url="https://tmuxp.git-pull.com/en/latest/"
+license=(MIT)
+depends=(python-click python-colorama python-kaptan python-libtmux)
+makedepends=(python-build python-installer python-poetry-core python-wheel)
+checkdepends=(python-pytest python-pytest-mock python-pytest-rerunfailures)
+source=(https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$pkgname-$pkgver.tar.gz)
+sha512sums=('bc1f777c6f5c897c6d1c322704b30db75f38e1af92f5ce075966e813ef8e5759ae5365464cf4afea4a1c867be3ea431239f658d840c472a105379533fb1e8824')
+b2sums=('ee8bb336494703678570262e44ff6482692f9d69f93d890128ca693bd25005263ef83efd23382bc202728e6de40082b0ae7c6346de369b5e119f52fc697d190e')
+
+build() {
+  cd $pkgname-$pkgver
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  local _deselected=(
+    # https://github.com/tmux-python/tmuxp/issues/788
+    --deselect tests/test_workspacebuilder.py::test_automatic_rename_option
+  )
+  cd $pkgname-$pkgver
+  pytest -vv "${_deselected[@]}"
+}
+
+package() {
+  cd $pkgname-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+
+  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+  install -vDm 644 {CHANGES,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
+  install -vDm 644 examples/*.{json,yaml} -t "$pkgdir/usr/share/doc/$pkgname/examples/"
+}
+
+# vim:set ts=2 sw=2 et:}