[arch-commits] Commit in intel-compute-runtime/repos/community-x86_64 (2 files)
Bruno Pagani
archange at gemini.archlinux.org
Tue Aug 2 18:17:56 UTC 2022
Date: Tuesday, August 2, 2022 @ 18:17:55
Author: archange
Revision: 1259860
archrelease: copy trunk to community-x86_64
Added:
intel-compute-runtime/repos/community-x86_64/PKGBUILD
(from rev 1259858, intel-compute-runtime/trunk/PKGBUILD)
Deleted:
intel-compute-runtime/repos/community-x86_64/PKGBUILD
----------+
PKGBUILD | 88 ++++++++++++++++++++++++++++---------------------------------
1 file changed, 41 insertions(+), 47 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2022-08-02 18:17:54 UTC (rev 1259859)
+++ PKGBUILD 2022-08-02 18:17:55 UTC (rev 1259860)
@@ -1,47 +0,0 @@
-# Maintainer: Daniel Bermond <dbermond at archlinux.org>
-# Maintainer: Bruno Pagani <archange at archlinux.org>
-
-pkgname=intel-compute-runtime
-pkgver=22.29.23750
-pkgrel=1
-pkgdesc="Intel(R) Graphics Compute Runtime for oneAPI Level Zero and OpenCL(TM) Driver"
-arch=(x86_64)
-url="https://01.org/compute-runtime"
-license=(MIT)
-depends=(gcc-libs intel-gmmlib intel-graphics-compiler)
-makedepends=(cmake libva level-zero-headers igsc)
-optdepends=('libva: for cl_intel_va_api_media_sharing'
- 'libdrm: for cl_intel_va_api_media_sharing')
-provides=(opencl-driver level-zero-driver)
-# https://github.com/intel/compute-runtime/issues/528
-options=(!lto)
-source=(https://github.com/intel/compute-runtime/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz
- ${pkgname}-fix-odr-issues.patch::https://github.com/intel/compute-runtime/commit/78c96db2faacdc3406a24a91f017aeae40b7ca54.patch)
-sha256sums=('c473fa8e2b2cd7d7df86287e3fe71d6c9252ee644f06ae12b9ce459df997b214'
- '0ede1c3dedeb41c4441938690c8d0e9e6a5dafdec530d45b35de3923fc12a6af')
-
-prepare() {
- patch -p1 -d compute-runtime-${pkgver} < ${pkgname}-fix-odr-issues.patch
-}
-
-build() {
- # ${${pkgver#*.}%.*} not supported by bash?
- cmake -B build -S compute-runtime-${pkgver} \
- -DCMAKE_BUILD_TYPE=Release \
- -DCMAKE_INSTALL_PREFIX=/usr \
- -DCMAKE_INSTALL_LIBDIR=lib \
- -DNEO_OCL_VERSION_MAJOR=${pkgver%%.*} \
- -DNEO_OCL_VERSION_MINOR=$(echo ${pkgver} | cut -d . -f2) \
- -DNEO_VERSION_BUILD=${pkgver##*.} \
- -DSUPPORT_DG1=ON \
- -Wno-dev
- make -C build
-}
-
-package() {
- make -C build DESTDIR="${pkgdir}" install
- install -Dm755 build/bin/libocloc.so -t "${pkgdir}"/usr/lib/intel-opencl
- install -Dm644 compute-runtime-${pkgver}/LICENSE.md -t "${pkgdir}"/usr/share/licenses/${pkgname}
-
- ln -s $(find "${pkgdir}"/usr/lib -regex '.*libze_intel_gpu.so.[0-9]*' -exec basename {} \;) "${pkgdir}"/usr/lib/libze_intel_gpu.so
-}
Copied: intel-compute-runtime/repos/community-x86_64/PKGBUILD (from rev 1259858, intel-compute-runtime/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2022-08-02 18:17:55 UTC (rev 1259860)
@@ -0,0 +1,41 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgname=intel-compute-runtime
+pkgver=22.30.23789
+pkgrel=1
+pkgdesc="Intel(R) Graphics Compute Runtime for oneAPI Level Zero and OpenCL(TM) Driver"
+arch=(x86_64)
+url="https://01.org/compute-runtime"
+license=(MIT)
+depends=(gcc-libs intel-gmmlib intel-graphics-compiler)
+makedepends=(cmake libva level-zero-headers igsc)
+optdepends=('libva: for cl_intel_va_api_media_sharing'
+ 'libdrm: for cl_intel_va_api_media_sharing')
+provides=(opencl-driver level-zero-driver)
+# https://github.com/intel/compute-runtime/issues/528
+options=(!lto)
+source=(https://github.com/intel/compute-runtime/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('f59e435de687c3719b54119437e4c9a574a98466a38f532572a1367efde8e964')
+
+build() {
+ # ${${pkgver#*.}%.*} not supported by bash?
+ cmake -B build -S compute-runtime-${pkgver} \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DNEO_OCL_VERSION_MAJOR=${pkgver%%.*} \
+ -DNEO_OCL_VERSION_MINOR=$(echo ${pkgver} | cut -d . -f2) \
+ -DNEO_VERSION_BUILD=${pkgver##*.} \
+ -DSUPPORT_DG1=ON \
+ -Wno-dev
+ make -C build
+}
+
+package() {
+ make -C build DESTDIR="${pkgdir}" install
+ install -Dm755 build/bin/libocloc.so -t "${pkgdir}"/usr/lib/intel-opencl
+ install -Dm644 compute-runtime-${pkgver}/LICENSE.md -t "${pkgdir}"/usr/share/licenses/${pkgname}
+
+ ln -s $(find "${pkgdir}"/usr/lib -regex '.*libze_intel_gpu.so.[0-9]*' -exec basename {} \;) "${pkgdir}"/usr/lib/libze_intel_gpu.so
+}
More information about the arch-commits
mailing list