[arch-commits] Commit in python-rapidfuzz (3 files)

[Antonio Rojas]

    Date: Wednesday, August 3, 2022 @ 10:26:04
  Author: arojas
Revision: 1259992

archrelease: copy trunk to community-x86_64

Added:
  python-rapidfuzz/repos/
  python-rapidfuzz/repos/community-x86_64/
  python-rapidfuzz/repos/community-x86_64/PKGBUILD
    (from rev 1259991, python-rapidfuzz/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: python-rapidfuzz/repos/community-x86_64/PKGBUILD (from rev 1259991, python-rapidfuzz/trunk/PKGBUILD)
===================================================================
--- repos/community-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-x86_64/PKGBUILD	2022-08-03 10:26:04 UTC (rev 1259992)
@@ -0,0 +1,39 @@
+# Maintainer:
+# Contributor: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+# Contributor: Caltlgin Stsodaat <contact at fossdaily.xyz>
+
+_pkgname=rapidfuzz
+pkgname=python-$_pkgname
+pkgver=2.4.2
+pkgrel=2
+pkgdesc='Rapid fuzzy string matching in Python using various string metrics'
+arch=(x86_64)
+url='https://github.com/maxbachmann/rapidfuzz'
+license=(MIT)
+depends=(python-jarowinkler)
+makedepends=(python-build python-installer python-scikit-build python-rapidfuzz-capi)
+checkdepends=(python-hypothesis python-pandas python-pytest)
+optdepends=(python-numpy)
+source=(https://files.pythonhosted.org/packages/source/${_pkgname::1}/$_pkgname/$_pkgname-$pkgver.tar.gz)
+sha256sums=('5046d8beaa829e4bc172014a006fa78825643fa39589cbf96f0e7bb098f1e973')
+
+build() {
+  cd $_pkgname-$pkgver
+  RAPIDFUZZ_BUILD_EXTENSION=1 \
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd $_pkgname-$pkgver
+  python -m venv --system-site-packages test-env
+  test-env/bin/python -m installer dist/*.whl
+  test-env/bin/python -m pytest
+}
+
+package() {
+  cd $_pkgname-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+
+  install -Dm644 README.md -t "$pkgdir"/usr/share/doc/$pkgname
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}