[arch-commits] Commit in (3 files)

Antonio Rojas arojas at gemini.archlinux.org
Thu Aug 4 07:54:52 UTC 2022


    Date: Thursday, August 4, 2022 @ 07:54:52
  Author: arojas
Revision: 1260227

New python-scipy dependency

Added:
  meson-python/
  meson-python/trunk/
  meson-python/trunk/PKGBUILD

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Added: meson-python/trunk/PKGBUILD
===================================================================
--- meson-python/trunk/PKGBUILD	                        (rev 0)
+++ meson-python/trunk/PKGBUILD	2022-08-04 07:54:52 UTC (rev 1260227)
@@ -0,0 +1,37 @@
+# Maintainer:
+
+pkgname=meson-python
+pkgver=0.8.1
+pkgrel=1
+pkgdesc='Meson PEP 517 Python build backend'
+arch=(any)
+url='https://github.com/FFY00/meson-python'
+license=(MIT)
+depends=(meson patchelf python-wheel python-pyproject-metadata)
+makedepends=(python-build python-installer ninja)
+checkdepends=(python-pytest python-gitpython python-pytest-mock)
+source=(https://github.com/FFY00/meson-python/archive/$pkgver/$pkgname-$pkgver.tar.gz)
+sha256sums=('dee3bef46970daef7d887f69aaf52812e470beb6e00c937b3a3185097c2bd392')
+
+prepare() {
+  cd $pkgname-$pkgver
+  sed -e '/ninja/d' -i pyproject.toml
+}
+
+build() {
+  cd $pkgname-$pkgver
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd $pkgname-$pkgver
+  python -m venv --system-site-packages test-env
+  test-env/bin/python -m installer dist/*.whl
+  test-env/bin/python -m pytest
+}
+
+package() {
+  cd $pkgname-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}



More information about the arch-commits mailing list