[arch-commits] Commit in python-scipy/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Antonio Rojas]

    Date: Thursday, August 4, 2022 @ 09:36:44
  Author: arojas
Revision: 1260238

archrelease: copy trunk to community-x86_64

Added:
  python-scipy/repos/community-x86_64/PKGBUILD
    (from rev 1260237, python-scipy/trunk/PKGBUILD)
Deleted:
  python-scipy/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   95 ++++++++++++++++++++++++++++++++-----------------------------
 1 file changed, 50 insertions(+), 45 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-08-04 09:36:35 UTC (rev 1260237)
+++ PKGBUILD	2022-08-04 09:36:44 UTC (rev 1260238)
@@ -1,45 +0,0 @@
-# Maintainer: Antonio Rojas <arojas at archlinux.org>
-# Contributor: Thomas Dziedzic < gostrc at gmail >
-# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
-# Contributor: Ray Rashif <schiv at archlinux.org>
-# Contributor: Douglas Soares de Andrade <dsa at aur.archlinux.org>
-# Contributor: Bodor Dávid Gábor <david.gabor.bodor at gmail.com>
-# Contributor: Andrzej Giniewicz <gginiu at gmail.com>
-
-_name=scipy
-pkgname=python-scipy
-pkgver=1.9.0
-pkgrel=1
-pkgdesc='Open-source software for mathematics, science, and engineering'
-arch=(x86_64)
-url='https://www.scipy.org/'
-license=(BSD)
-depends=(python-numpy)
-provides=(scipy)
-makedepends=(gcc-fortran python-setuptools cython python-pythran pybind11)
-checkdepends=(python-pytest)
-optdepends=('python-pillow: for image saving module')
-source=(https://pypi.python.org/packages/source/${_name:0:1}/$_name/$_name-$pkgver.tar.gz)
-sha256sums=('c0dfd7d2429452e7e94904c6a3af63cbaa3cf51b348bd9d35b42db7e9ad42791')
-
-build() {
-  cd scipy-${pkgver}
-  python setup.py config_fc build
-}
-
-check() {
-  cd scipy-${pkgver}
-  python setup.py config_fc install \
-    --prefix=/usr --root="$srcdir"/test --optimize=1
-  export PYTHONPATH="$srcdir"/test/usr/lib/python3.10/site-packages
-  cd ..
-  python -c "from scipy import test; test('full')"
-}
-
-package() {
-  cd scipy-$pkgver
-  python3 setup.py config_fc install \
-    --prefix=/usr --root="$pkgdir" --optimize=1
-
-  install -Dm644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
-}

Copied: python-scipy/repos/community-x86_64/PKGBUILD (from rev 1260237, python-scipy/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-08-04 09:36:44 UTC (rev 1260238)
@@ -0,0 +1,50 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: Douglas Soares de Andrade <dsa at aur.archlinux.org>
+# Contributor: Bodor Dávid Gábor <david.gabor.bodor at gmail.com>
+# Contributor: Andrzej Giniewicz <gginiu at gmail.com>
+
+_name=scipy
+pkgname=python-scipy
+pkgver=1.9.0
+pkgrel=2
+pkgdesc='Open-source software for mathematics, science, and engineering'
+arch=(x86_64)
+url='https://www.scipy.org/'
+license=(BSD)
+depends=(python-numpy)
+provides=(scipy)
+makedepends=(gcc-fortran cython python-pythran pybind11 meson-python python-build python-installer)
+checkdepends=(python-pytest)
+optdepends=('python-pillow: for image saving module')
+source=(https://pypi.python.org/packages/source/${_name:0:1}/$_name/$_name-$pkgver.tar.gz)
+sha256sums=('c0dfd7d2429452e7e94904c6a3af63cbaa3cf51b348bd9d35b42db7e9ad42791')
+
+prepare() {
+  cd $_name-$pkgver
+# meson-python does not allow passing options to meson yet
+  sed -e 's|blas=openblas|blas=blas|' -e 's|lapack=openblas|lapack=lapack|' -i meson.build
+# Relax dependency versions
+  sed -e 's|==|>=|g' -e 's|\,<[0-9]*\(.[0-9]\)*||g' -i pyproject.toml
+}
+
+build() {
+  cd $_name-$pkgver
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd $_name-$pkgver
+  python -m venv --system-site-packages test-env
+  test-env/bin/python -m installer dist/*.whl
+  cd test-env
+  bin/python -c "from scipy import test; test('full')"
+}
+
+package() {
+  cd $_name-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -Dm644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
+}