[arch-commits] Commit in neovim-qt/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Alexander Rødseth]

    Date: Thursday, August 4, 2022 @ 18:31:42
  Author: arodseth
Revision: 1260281

archrelease: copy trunk to community-x86_64

Added:
  neovim-qt/repos/community-x86_64/PKGBUILD
    (from rev 1260280, neovim-qt/trunk/PKGBUILD)
Deleted:
  neovim-qt/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   83 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 41 insertions(+), 42 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-08-04 18:31:37 UTC (rev 1260280)
+++ PKGBUILD	2022-08-04 18:31:42 UTC (rev 1260281)
@@ -1,42 +0,0 @@
-# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
-# Contributor: Aleksandar Trifunović <akstrfn at gmail.com>
-# Contributor: Iván Ruvalcaba <mario.i.ruvalcaba at gmail.com>
-# Contributor: Ian Ker-Seymer <i.kerseymer at gmail.com>
-
-pkgname=neovim-qt
-pkgver=0.2.17
-pkgrel=1
-pkgdesc='GUI for Neovim'
-arch=(x86_64)
-url='https://github.com/equalsraf/neovim-qt'
-license=(ISC)
-depends=(neovim qt5-svg hicolor-icon-theme)
-makedepends=(cmake git ninja xorg-server-xvfb)
-source=("git+$url#commit=3f05de82ecb5c1a24a7572081ae59e419eb059b8") # tag: v0.2.17
-b2sums=('SKIP')
-
-build() {
-  cmake \
-    -B build \
-    -D CMAKE_BUILD_TYPE=Release \
-    -D CMAKE_C_FLAGS="$CFLAGS" \
-    -D CMAKE_CXX_FLAGS="$CXXFLAGS" \
-    -D CMAKE_EXE_LINKER_FLAGS="$LDFLAGS" \
-    -D CMAKE_INSTALL_LIBDIR=lib \
-    -D CMAKE_INSTALL_PREFIX=/usr \
-    -D USE_SYSTEM_MSGPACK=on \
-    -G Ninja \
-    -S $pkgname
-  ninja -C build
-}
-
-# One of the tests fails when building in a chroot
-# https://github.com/equalsraf/neovim-qt/issues/1005
-#check() {
-#  xvfb-run ninja -v -C build test
-#}
-
-package() {
-  DESTDIR="$pkgdir" ninja -C build install
-  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" "$pkgname/LICENSE"
-}

Copied: neovim-qt/repos/community-x86_64/PKGBUILD (from rev 1260280, neovim-qt/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-08-04 18:31:42 UTC (rev 1260281)
@@ -0,0 +1,41 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Aleksandar Trifunović <akstrfn at gmail.com>
+# Contributor: Iván Ruvalcaba <mario.i.ruvalcaba at gmail.com>
+# Contributor: Ian Ker-Seymer <i.kerseymer at gmail.com>
+
+pkgname=neovim-qt
+pkgver=0.2.17
+pkgrel=2
+pkgdesc='GUI for Neovim'
+arch=(x86_64)
+url='https://github.com/equalsraf/neovim-qt'
+license=(ISC)
+depends=(neovim qt5-svg hicolor-icon-theme)
+makedepends=(cmake git ninja)
+checkdepends=(ttf-dejavu xorg-server-xvfb)
+source=("git+$url#commit=3f05de82ecb5c1a24a7572081ae59e419eb059b8") # tag: v0.2.17
+b2sums=('SKIP')
+
+build() {
+  cmake \
+    -B build \
+    -D CMAKE_BUILD_TYPE=Release \
+    -D CMAKE_C_FLAGS="$CFLAGS" \
+    -D CMAKE_CXX_FLAGS="$CXXFLAGS" \
+    -D CMAKE_EXE_LINKER_FLAGS="$LDFLAGS" \
+    -D CMAKE_INSTALL_LIBDIR=lib \
+    -D CMAKE_INSTALL_PREFIX=/usr \
+    -D USE_SYSTEM_MSGPACK=on \
+    -G Ninja \
+    -S $pkgname
+  ninja -C build
+}
+
+check() {
+  xvfb-run ninja -v -C build test
+}
+
+package() {
+  DESTDIR="$pkgdir" ninja -C build install
+  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" "$pkgname/LICENSE"
+}