[arch-commits] Commit in (4 files)

[George Rawlinson]

    Date: Friday, August 5, 2022 @ 00:09:53
  Author: grawlinson
Revision: 1260289

addpkg: alsa-scarlett-gui 0.2-2

Added:
  alsa-scarlett-gui/
  alsa-scarlett-gui/repos/
  alsa-scarlett-gui/trunk/
  alsa-scarlett-gui/trunk/PKGBUILD

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Added: alsa-scarlett-gui/trunk/PKGBUILD
===================================================================
--- alsa-scarlett-gui/trunk/PKGBUILD	                        (rev 0)
+++ alsa-scarlett-gui/trunk/PKGBUILD	2022-08-05 00:09:53 UTC (rev 1260289)
@@ -0,0 +1,54 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+
+pkgname=alsa-scarlett-gui
+pkgver=0.2
+pkgrel=2
+pkgdesc='GUI for the ALSA controls presented by the Focusrite Scarlett Gen 2/3 mixer driver'
+arch=('x86_64')
+url='https://github.com/geoffreybennett/alsa-scarlett-gui'
+license=('GPL3' 'LGPL3')
+depends=('gtk4' 'alsa-lib')
+makedepends=('git')
+_commit='d085fd49c1a8ef3dda348d06b1d7381adccaaf2f'
+source=("$pkgname::git+$url#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+prepare() {
+  cd "$pkgname"
+
+  # remove incorrect keys in desktop file
+  sed \
+    -i src/vu.b4.alsa-scarlett-gui.desktop.template \
+    -e '/^Value=.*/d' \
+    -e '/^Encoding=.*/d'
+}
+
+build() {
+  cd "$pkgname"
+
+  make \
+    -C src \
+    PREFIX=/usr \
+    VERSION="$pkgver"
+}
+
+package() {
+  cd "$pkgname"
+
+  make \
+    -C src \
+    PREFIX="$pkgdir/usr" \
+    VERSION="$pkgver" \
+    install
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname/img" img/*
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname/demo" demo/*
+}