[arch-commits] Commit in (5 files)
George Rawlinson
grawlinson at gemini.archlinux.org
Fri Aug 5 23:42:19 UTC 2022
Date: Friday, August 5, 2022 @ 23:42:19
Author: grawlinson
Revision: 1260356
addpkg: sws 2.13.1.0-1
Added:
sws/
sws/repos/
sws/trunk/
sws/trunk/PKGBUILD
sws/trunk/sws.install
-------------+
PKGBUILD | 73 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
sws.install | 10 +++++++
2 files changed, 83 insertions(+)
Added: sws/trunk/PKGBUILD
===================================================================
--- sws/trunk/PKGBUILD (rev 0)
+++ sws/trunk/PKGBUILD 2022-08-05 23:42:19 UTC (rev 1260356)
@@ -0,0 +1,73 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: andre.menrath at posteo.de
+
+pkgname=sws
+pkgver=2.13.1.0
+pkgrel=1
+pkgdesc='A collection of features that seamlessly integrate into REAPER'
+arch=('x86_64')
+url='https://www.sws-extension.org/'
+license=('MIT')
+depends=(
+ 'gcc-libs'
+ 'reaper'
+ 'taglib'
+)
+makedepends=(
+ 'git'
+ 'cmake'
+ 'php'
+ 'perl'
+ 'gtk3'
+)
+install='sws.install'
+_commit='60104cef02f75c6ce75bb2ae3ae119e5e9221825'
+source=(
+ "git+https://github.com/reaper-oss/sws.git#commit=$_commit"
+ 'github.com-justinfrankel-wdl::git+https://github.com/justinfrankel/WDL'
+ 'github.com-justinfrankel-reaper-sdk::git+https://github.com/justinfrankel/reaper-sdk'
+)
+b2sums=('SKIP'
+ 'SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd "$pkgname"
+
+ head -n 1 version.h.in | cut -d ' ' -f 3 | tr , .
+}
+
+prepare() {
+ cd "$pkgname"
+
+ # prepare git submodule(s)
+ # note: vendor/taglib submodule is skipped because we use system taglib
+ git submodule init vendor/WDL vendor/reaper-sdk
+ git config submodule.vendor/WDL.url "$srcdir/github.com-justinfrankel-wdl"
+ git config submodule.vendor/reaper-sdk.url "$srcdir/github.com-justinfrankel-reaper-sdk"
+ git submodule update vendor/WDL vendor/reaper-sdk
+}
+
+build() {
+ cmake \
+ -B build \
+ -S "$pkgname" \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DUSE_SYSTEM_TAGLIB=YES
+
+ cmake --build build
+}
+
+package() {
+ # plugin
+ install -vDm755 -t "$pkgdir/usr/lib/sws" "build/reaper_sws-$CARCH.so"
+ install -vDm644 -t "$pkgdir/usr/lib/sws" build/sws_python64.py
+
+ cd "$pkgname"
+
+ # documentation
+ install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md whatsnew.txt
+
+ # license
+ install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" COPYING
+}
Added: sws/trunk/sws.install
===================================================================
--- sws/trunk/sws.install (rev 0)
+++ sws/trunk/sws.install 2022-08-05 23:42:19 UTC (rev 1260356)
@@ -0,0 +1,10 @@
+post_install(){
+ cat <<- EOF
+
+For REAPER to pick up the plugin, it must be symlinked into REAPER's user directory.
+
+ln -s /usr/lib/sws/reaper_sws-x86_64.so ~/.config/REAPER/UserPlugins/
+ln -s /usr/lib/sws/sws_python64.py ~/.config/REAPER/Scripts/
+
+EOF
+}
More information about the arch-commits
mailing list