[arch-commits] Commit in scons/repos/extra-any (PKGBUILD PKGBUILD)

[David Runge]

    Date: Sunday, August 7, 2022 @ 11:56:29
  Author: dvzrv
Revision: 452387

archrelease: copy trunk to extra-any

Added:
  scons/repos/extra-any/PKGBUILD
    (from rev 452386, scons/trunk/PKGBUILD)
Deleted:
  scons/repos/extra-any/PKGBUILD

----------+
 PKGBUILD |   86 +++++++++++++++++++++++++++++--------------------------------
 1 file changed, 41 insertions(+), 45 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-08-07 11:56:19 UTC (rev 452386)
+++ PKGBUILD	2022-08-07 11:56:29 UTC (rev 452387)
@@ -1,45 +0,0 @@
-# Maintainer: David Runge <dvzrv at archlinux.org>
-# Contributor: Ray Rashif <schiv at archlinux.org>
-# Contributor: damir <damir at archlinux.org>
-# Contributor: Lukas Sabota <punkrockguy318 at comcast.net>
-# Contributor: Brice Carpentier <brice at dlfp.org>
-
-pkgname=scons
-pkgver=4.3.0
-pkgrel=3
-pkgdesc="Extensible Python-based build utility"
-arch=(any)
-url="https://scons.org"
-license=(MIT)
-depends=(python)
-makedepends=(python-setuptools python-sphinx python-sphinx_rtd_theme
-rst2pdf)
-checkdepends=(python-pytest)
-source=("$pkgname-$pkgver.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/${pkgver}.tar.gz")
-sha512sums=('2d91cf3045797c888d24db38d5b44576e56b271a2c4e9d28d7e16026451865f713990ff9e57fa3e0a1c19603c2d6adbbd1ba36d297c9dcce4db4139fcc51cd62')
-b2sums=('a43b509b358d47ee73f7eb714d1239b4fdc33f38483c1a3e72c3a8082242d7bb1a4925958a2648782aa28f4c22a6e018aea8fec1139cf44c59e859f6f902d1d3')
-
-prepare() {
-  cd "${pkgname}-${pkgver}"
-  # fix wrong build target
-  sed -e 's/bdist_wheel/bdist/g' -i SConstruct
-}
-
-build() {
-  cd "${pkgname}-${pkgver}"
-  python scripts/scons.py --include-dir= -j1
-  # copy man pages into place, so that install-data may pick them up
-  cp -av build/doc/man/* .
-}
-
-check() {
-  cd "${pkgname}-${pkgver}"
-  python runtest.py --all --unit-only
-}
-
-package() {
-  cd "${pkgname}-${pkgver}"
-  python setup.py install --optimize=1 --install-data=/usr/share/man/man1/ --root="$pkgdir"
-  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
-  install -vDm 644 {{CHANGES,RELEASE}.txt,README.rst} -t "${pkgdir}/usr/share/doc/${pkgname}/"
-}

Copied: scons/repos/extra-any/PKGBUILD (from rev 452386, scons/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-08-07 11:56:29 UTC (rev 452387)
@@ -0,0 +1,41 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: damir <damir at archlinux.org>
+# Contributor: Lukas Sabota <punkrockguy318 at comcast.net>
+# Contributor: Brice Carpentier <brice at dlfp.org>
+
+pkgname=scons
+pkgver=4.4.0
+pkgrel=1
+pkgdesc="Extensible Python-based build utility"
+arch=(any)
+url="https://scons.org"
+license=(MIT)
+depends=(python)
+makedepends=(ninja python-build python-installer python-lxml python-setuptools
+python-sphinx python-sphinx_rtd_theme python-wheel rst2pdf)
+checkdepends=(python-psutil python-pytest)
+source=($pkgname-$pkgver.tar.gz::https://github.com/$pkgname/$pkgname/archive/$pkgver.tar.gz)
+sha512sums=('01fcd40bf818ca22a278973af1cda3024efb74cf877f15d46607fda860448fbd577fc96ba33fef2bed3d145e662a0371f55e8c927e7ac44feea7f3081791ce11')
+b2sums=('f6ce757f2edc40551b05285098626bb62def6abda2380d4885ee4443868e715e53aaa34f26c09dc689bb6ade26d1b0e276046fe3b1d2ddf8eb40400bca9ea164')
+
+build() {
+  cd $pkgname-$pkgver
+  python scripts/scons.py --include-dir= -j1
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd $pkgname-$pkgver
+  python runtest.py --all --unit-only
+}
+
+package() {
+  cd $pkgname-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  # remove man pages wrongly installed due to mishandling of install-data
+  rm -fv "$pkgdir/usr/"*.1
+  install -vDm 644 build/doc/man/* -t "$pkgdir/usr/share/man/man1/"
+  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+  install -vDm 644 {{CHANGES,RELEASE}.txt,README.rst} -t "$pkgdir/usr/share/doc/$pkgname/"
+}